Re^2: Manipulate deepest values in complex hash structures

enough theory, now practical code:

use strict;
use warnings;
use Data::Dump qw/pp/;
use Scalar::Util qw/reftype/;

sub walk {
  my ($entry,$code) =@_;
  my $type = reftype($entry);
  $type //= "SCALAR";

  if    ($type eq "HASH") {
    walk($_,$code) for values %$entry;
  }
  elsif ($type eq "ARRAY") {
    walk($_,$code) for @$entry;
  }
  elsif ($type eq "SCALAR" ) {
    $code->($_[0]);        # alias of entry
  }
  else {
    warn "unknown type $type";
  }
}


my $test = { a => [2, 3, [4, { b => 42 }]], c => 5 };

pp $test;
walk $test, sub { $_[0]+=100 };
pp $test;
[download]

Output

/usr/bin/perl -w /tmp/walker.pl 
{ a => [2, 3, [4, { b => 42 }]], c => 5 }
{ a => [102, 103, [104, { b => 142 }]], c => 105 }
[download]

Cheers Rolf

( addicted to the Perl Programming Language)

UPDATE

of course you could extend walk to call optional $coderefs on every node and specify them as named parameters:

walk $ref , SCALAR => sub { print $_[0] } , ARRAY => sub { Dump $_[0] }, ...

But I think the original code is so small thats its easier to copy and manipulate it in place for different needs.

Comment on Re^2: Manipulate deepest values in complex hash structures Select or Download Code

Replies are listed 'Best First'.
Re^3: Manipulate deepest values in complex hash structures by pachydermic (Beadle) on May 01, 2013 at 17:07 UTC
Great post, LanX. I have two questions: For the line: `$type //= "SCALAR";` am I correct in thinking that this is using the or operator as you would like += or .=? So that $type takes the value "SCALAR" if it doesn't already have a value? I looked in perlop, but I wasn't aware you could use logical operators like that... My second question is how `$code->($_[0]);` performs the operation on $_[0]. Currently I'm trying to become more comfortable with references (and they're very confusing), so I'd appreciate it if you could point me in the correct direction. I've already read http://perldoc.perl.org/perlreftut.html, but I'm trying to make it stick now. Thanks in advance!	[reply] [d/l] [select]
Re^4: Manipulate deepest values in complex hash structures by LanX (Sage) on May 01, 2013 at 17:38 UTC
> am I correct in thinking that this is using the or operator as you would like += or .= almost, you are describing `\|\|=` which assigns if the left side is false. you can find this combination in many languages. But current Perl versions also have `//` for defined-or, which only act on `undef` and not other false values. so `$type //= "SCALAR"` means `$type = defined $type ? $type : "SCALAR";` > performs the operation on $_[0]. Currently I'm trying to become more comfortable with references (and they're very confusing) It's even more confusing, cause it's not a reference but an alias. Changing elements of @_ means directly changing the passed arguments (see perlsub). Ironically references shouldn't be confusing, because in most languages arrays and hashes are always copied as references and automatically dereferenced. Perl is one of the rare languages which make a distinction between two flavours. In JS for instance something like `a=[];b=a; a[1]=42; b[1] == 42` is true, because `a` and `b` are references to the same array. In Perl you need to explicitly copy references to achieve this, since `@b=@a` only copies the elements. But alternatively you can do like JS does with references: `$a=[]; $b=$a; $a->[1]=42; $b->[1] == 42` Cheers Rolf ( addicted to the Perl Programming Language)	[reply] [d/l] [select]


Think about Loose Coupling
	PerlMonks