use warnings;
[download]

is short for

BEGIN {
   require warnings;
   import warnings;
}
[download]

so you could do

BEGIN {
   my $debug = 1;
   if ($debug) {
      require warnings;
      import warnings;
   }
}
[download]

The if module attempts to clean that up:

my $debug;
BEGIN { $debug = 1; }
use if $debug, 'warnings';
[download]

warnings is lexically scoped.

• perldoc -f use
• perldoc if

By the way, you need to hide the 'use module' within an eval, to control whether it happens or not, or else use the module 'if' ( use if CONDITION, MODULE => ARGS ).

Using eval would delay the directive to runtime, but it needs to be active at runtime to affect code.

>perl -e"eval 'use warnings; 1' or die $@; print undef;"

>perl -e"use warnings; print undef;"
Use of uninitialized value in print at -e line 1.
[download]

And you can't wrap it in a BEGIN because that would introduce a lexical scope.

#!/usr/bin/perl -l

use strict;
use CGI;
use Test::SubCalls;
use Test::More tests => 2;

BEGIN {
    my $debug = 1;
    if ($debug) { 
        require warnings;
        import warnings;
    }
}
print "Using warnings";
sub_track( 'CGI::new' );

my $q1 = CGI->new;
my $q2 = CGI->new;

sub_calls( 'CGI::new', 2, "Running" );
sub_calls( 'CGI::new', 2, "Ran" );
done_testing(2);
[download]

BEGIN {
    my $debug = 0;
    unless ($debug) {
        $INC {"warnings.pm"} = 1;
        no strict 'refs';
        *{"warnings::import"} = sub {1;};
    }
}

use warnings;
[download]

If you can live with just one category enabled if debugging is off, you could do:

BEGIN {
    $::DEBUG = 1;
}
use warnings $::DEBUG ? "all" : "io";  # Or some other category.
[download]

use if (1 == 1), warnings => qw(all);
[download]

am thinking that an eval on $debug *requires* the compiler, therefore compiler directives like "strict, warnings, diagnostics, etc." cannot be loaded in this manner (however, I'm often wrong). For more, see:

I think what you were looking for is

$ perl -E 'BEGIN {our $debug = 1;} use if $debug // 0, warnings; say u
+ndef'
Use of uninitialized value in say at -e line 1.
[download]

although I would be inclined to go with an environment variable instead, to avoid having to edit the source code:

$ debug=1 perl -E 'use if $ENV{debug} // 0, warnings; say undef'
Use of uninitialized value in say at -e line 1.
[download]

To a certain extent, the use declaration is, shall we say, “overloaded.”   In some ways it is a lot like require, whereas in other ways it absolutely is not.   Here is another case where Perl might have infuriated semantic purists, in favor of being a pragmatically useful tool.   I suggest that you always treat the statement as a declaration, not as an executable statement.   Put all of the necessary declarations at the beginning of the module (beginning always with use strict; use warnings;), and leave them there.

Am much closer to the goal, now just stuck on the "inverse, sort of" (from the Camel Book) of "use", "no". Sorry, not meaning to be cryptic. Instead, here's some code that demonstrates what I was hoping to achieve:

use strict;
my $debug;

BEGIN { $debug = 3; }

use if ($debug > 0), 'warnings'; 
use if ($debug > 1), 'diagnostics';
if     ($debug > 2) { no warnings 'redefine'; }

run_sub();
sub run_sub { print "Running\n";}
sub run_sub { print "Ran\n";}

if ($debug > 3) {print "DEBUG: blah, blah, ...\n";}
[download]

Have tried a few modifications, but none eliminated the 'redefine' warnings when ($debug > 2).

Have tried a few modifications, but none eliminated the 'redefine' warnings when ($debug > 2).

That's because it has a lexical scope, and the scope in your code is the containing block. This ugly alternative works:

BEGIN { warnings->unimport( 'redefine' ) if $debug > 2 }

---

Improve your skills with Modern Perl: the free book.

It's not ugly - it's Perl. Thank you. Again, great explanations folks - your advice is very much appreciated.