That's interesting, but there are reasons other than performance for wanting fix-width integer semantics.

Try coding this with GMP (or any arbitrary precision math):

#! perl -slw
use strict;
use Math::Int128 qw[int128 uint128];

my $ZERO = uint128( 0 );
my $ONE  = uint128( 1 );
my $ALLONES = ~ $ZERO;
my $MASK1 = $ALLONES / 3;
my $MASK2 = $ALLONES / 15 * 3;
my $MASK3 = $ALLONES / 255;
my $MASK4 = $MASK3 * 15;

sub bcount {
    my $v = shift;
    $v = $v - ( ( $v >> 1 ) & $MASK1 );
    $v = ( $v & $MASK2 ) + ( ( $v >> 2 ) & $MASK2 );
    $v = ( $v + ( $v >> 4 ) ) &  $MASK4;
    my $c = ( $v * ( $MASK3 ) ) >> 120;
    return $c;
}

my $bits = uint128( 0 );

## set every 3rd bit
$bits |= $ONE << $_ for map $_*3+1, 0 .. 42;
print $bits;

## count the bits (43)
print bcount( $bits );

## now invert them and count again. (85)
print bcount( ~$bits );

__END__
c:\test>m128.pl
194447066811964836264785489961010406546
43
85
[download]

Note: I would have supplied a GMPz version, but I couldn't work out how to do it from the docs. There seem to be a million ways to initialise a number; a million ways to divide two numbers etc, But not so much when it comes to doing bitwise math.

Update: Here's my attempt at a GMP version of the above. Note that it doesn't just produce the wrong results, but it does so silently:

#! perl -slw
use strict;
use Math::GMPz;

my $ZERO = Math::GMPz->new( 0 );
my $ONE  = Math::GMPz->new( 1 );
my $ALLONES = ~ $ZERO;
my $MASK1 = $ALLONES / 3;
my $MASK2 = $ALLONES / 15 * 3;
my $MASK3 = $ALLONES / 255;
my $MASK4 = $MASK3 * 15;

sub bcount {
    my $v = shift;
    $v = $v - ( ( $v >> 1 ) & $MASK1 );
    $v = ( $v & $MASK2 ) + ( ( $v >> 2 ) & $MASK2 );
    $v = ( $v + ( $v >> 4 ) ) &  $MASK4;
    my $c = ( $v * ( $MASK3 ) ) >> 120;
    return $c;
}

my $bits = Math::GMPz->new( 0 );

## set every 3rd bit
$bits |= $ONE << $_ for map $_*3+1, 0 .. 42;
print $bits;

## count the bits (43)
print bcount( $bits );

## now invert them and count again. (85)
print bcount( ~$bits );

__END__
c:\test>gmpz-t.pl
194447066811964836264785489961010406546
0
0
[download]

there are reasons other than performance for wanting fix-width integer semantics

Definitely correct ... though I must confess that the reasons you've implicitly put forward in your demos were not exactly what I was thinking of when I acknowledged this (or tried to) in my earlier post.

For a Math::GMPz rendition of your demo I would put forward the following:

#! perl -slw
use strict;
use Math::GMPz qw(:mpz);

my $ZERO = Math::GMPz->new( 0 );
my $ONE  = Math::GMPz->new( 1 );
#my $ALLONES = ~ $ZERO;
my $ALLONES = (Math::GMPz->new(1) << 128) - 1;
my $MASK1 = $ALLONES / 3;
my $MASK2 = $ALLONES / 15 * 3;
my $MASK3 = $ALLONES / 255;
my $MASK4 = $MASK3 * 15;

my $bits = Math::GMPz->new( 0 );

## set every 3rd bit
$bits |= $ONE << $_ for map $_*3+1, 0 .. 42;
print $bits;
## count the bits (43)
#print bcount( $bits );
print Rmpz_popcount($bits);

## now invert them and count again. (85)
#print bcount( ~$bits );
print Rmpz_popcount($ALLONES ^ $bits);
[download]

I hope it doesn't miss the point ... I think the only changes are that:
1) It changes the way that $ALLONES is created;
2) It removes the need for sub bcount()

Update: And, there's also now a qw(:mpz) in the third line.

Cheers,
Rob

2) It removes the need for sub bcount()

That does miss the point, which was not what the bcount() sub did, but the way it did it.

The result of using bitwise math using arbitrary precision doesn't follow the fix-width integer semantics. Ie. the math isn't automatically module 2^128.

That means you get quite different results:

#! perl -slw
use strict;
use Math::GMPz;

my $ZERO = Math::GMPz->new( 0 );
my $ONE  = Math::GMPz->new( 1 );
#my $ALLONES = ~ $ZERO;
my $ALLONES = (Math::GMPz->new(1) << 128) - 1;
my $MASK1 = $ALLONES / 3;
my $MASK2 = $ALLONES / 15 * 3;
my $MASK3 = $ALLONES / 255;
my $MASK4 = $MASK3 * 15;

sub bcount {
    my $v = shift;
    $v = $v - ( ( $v >> 1 ) & $MASK1 );
    $v = ( $v & $MASK2 ) + ( ( $v >> 2 ) & $MASK2 );
    $v = ( $v + ( $v >> 4 ) ) &  $MASK4;
    my $c = ( $v * ( $MASK3 ) ) >> 120;
    return $c;
}

my $bits = Math::GMPz->new( 0 );

## set every 3rd bit
$bits |= $ONE << $_ for map $_*3+1, 0 .. 42;
print $bits;

## count the bits (43)
print bcount( $bits );

## now invert them and count again. (85)
print bcount( ~$bits );

__END__
C:\test>gmpz-t.pl
194447066811964836264785489961010406546
4019000903644796537894933644280473643
6698389137940470254461716813547458644
[download]

---

Examine what is said, not who speaks -- Silence betokens consent -- Love the truth but pardon error.

"Science is about questioning the status quo. Questioning authority".

In the absence of evidence, opinion is indistinguishable from prejudice.

but I don't see much scope for improvement at the moment

Well, there is...

The G2 version is faster than G1 and I because it is not allocating and deallocating the result object every time but reusing $mpz_ret.

After adding to Math::Int128 a new set of operators that use a preallocated argument for output, Math::Int128 becomes faster than Math::GMPz, around 60% faster.

The modified benchmark script:

And the results I get on my 64bits-linux-but-with-a-not-very-optimized-for-64bits-old-processor:

******************
**MULTIPLICATION**
******************

               Rate mul_M::G1  mul_M::I mul_M::G2 mul_M::I2
mul_M::G1  321555/s        --      -72%      -87%      -91%
mul_M::I  1147836/s      257%        --      -52%      -69%
mul_M::G2 2406041/s      648%      110%        --      -35%
mul_M::I2 3709585/s     1054%      223%       54%        --

******************
*****DIVISION*****
******************

               Rate div_M::G1  div_M::I div_M::G2 div_M::I2
div_M::G1  314139/s        --      -71%      -83%      -88%
div_M::I  1092266/s      248%        --      -39%      -59%
div_M::G2 1799026/s      473%       65%        --      -32%
div_M::I2 2633983/s      738%      141%       46%        --

******************
*****ADDITION*****
******************

               Rate add_M::G1  add_M::I add_M::G2 add_M::I2
add_M::G1  317021/s        --      -71%      -86%      -91%
add_M::I  1092266/s      245%        --      -51%      -70%
add_M::G2 2248783/s      609%      106%        --      -38%
add_M::I2 3598054/s     1035%      229%       60%        --

******************
****SUBTRACTION***
******************

               Rate sub_M::G1  sub_M::I sub_M::G2 sub_M::I2
sub_M::G1  309967/s        --      -72%      -84%      -91%
sub_M::I  1113475/s      259%        --      -44%      -68%
sub_M::G2 1997468/s      544%       79%        --      -43%
sub_M::I2 3495253/s     1028%      214%       75%        --
[download]

Math::Int128 becomes faster than Math::GMPz, around 60%

Using the latest version of Math::Int128, and your modified script, I find an improvement (on Windows Vista) of around 40%. Given that we're using different operating systems and probably different processors, I think we can agree that "I find the same as you".

Cheers,
Rob

I should add that even 40% is better than I could get with my approach to Math::Int128 modifications. I might learn something if I ever find the time and energy to discover why that was so. (Best I could get was to have the int128 arithemtic about 5-10% faster than Math::GMPz.)

Well, I have been able to improve Math::Int128 significantly since yesterday. Now, on my computer, it is twice as fast as Math::GMPz running your benchmarks.

There were two kinds of improvements: providing the 3-argument operators (i.e. uint128_add($to, $a, $b)) and optimizing the SV to int128_t conversions.

I have also found that the code generated by GCC-current is quite unpredictable. Sometimes things that should be faster are slower. So the tunning I have carried out may be ineffective for your particular version of GCC.

After adding to Math::Int128 a new set of operators that use a preallocated argument for output, Math::Int128 becomes faster than Math::GMPz, around 60% faster

That's more like the figures I anticipated (at a guess).
My "I don't see much scope for improvement" comment was in relation to my own enhancements to Math::Int128 which removed the allocating/deallocating you mentioned - and which made the int128 multiplication a little faster than using Math::GMPz's functions (and, of course, significantly faster than using Math::GMPz's overloaded operators).

When I get back to my Vista64 box, I'll grab the latest github version and see for myself ... and, of course, post again with my results for that machine.

Cheers,
Rob