Update 2: This module has been cleaned up a little bit and some small features added (not updated in the code in this node), and I've uploaded it to CPAN as Time::Fake. It will appear on CPAN after the normal processing time...

---

Here's a little module that I just threw together. It overrides the builtin time sub (Update: and also localtime and gmtime) to adjust the output by some offset:

package TimeOffset;

sub import {
    my $pkg = shift;
    my $offset = shift || "+0";

    if ($offset !~ /^[+-]/) {
       $offset = $offset - time;
    }

    *CORE::GLOBAL::time = sub { CORE::time() + $offset };

    *CORE::GLOBAL::localtime = sub {
       return @_ ? CORE::localtime(@_)
                 : CORE::localtime(CORE::time() + $offset);
    };

    *CORE::GLOBAL::gmtime = sub {
       return @_ ? CORE::gmtime(@_)
                 : CORE::gmtime(CORE::time() + $offset);
    };
}

1;
[download]

You can use this as follows:

use TimeOffset '+3600'; # pretend it's 1hr in the future
[download]

or

use TimeOffset '-60'; # pretend it's 1min in the past
[download]

or

use TimeOffset 12345678; # pretend the program was started
                         # at 12345678 epoch seconds
[download]

This is just a proof of concept but you can probably extend it to however your code figures out the current time. I.e, there may be other ways to obtain the time in perl that I haven't thought of.

Perhaps I could make this a little nicer, package it up, and send it off to CPAN? That is, if something like this really isn't on CPAN already..

Update: some caveats that I can think of, off the top of my head:

• doesn't affect -M, -A, -C filetest operators in the way you'd probably want. I belive these would still report *actual* script start time (not faked script start time) minus file access time.