I had a different solution in my Perl Hacks talk this summer; I'll write it up and post it somewhere soon.

Meanwhile, I suggest making the web process generate plain TAP and running that through Test::Harness yourself elsewhere. That ought to avoid most of the tricky problems there. Perhaps you can have an extra directory of applications, properly password-protected of course, that run the tests for you.

(Be sure to redirect STDERR and STDOUT to the same place before you load any test modules, or else you likely won't get diagnostic output.)

/my/base_dir/t/
/my/base_dir/t/BaseSystems/
/my/base_dir/t/BaseSystems/0_foo.t
/my/base_dir/t/BaseSystems/1_bar.t
/my/base_dir/t/MainSystem/0_test_something.t
[download]

#!/usr/bin/perl

=head1 NAME

cgi_prove - Web based interface to /usr/bin/prove

=cut

use base qw(CGI::Ex::App);
use strict;
use warnings;
use vars qw($BASE_DIR $LIB_DIR $PROVE_PROG);
use CGI::Ex::Dump qw(debug);

BEGIN {
    require config;
    $BASE_DIR = $config::config{'rootdir_server'} .'/t';
    $LIB_DIR  = $config::config{'rootdir_server'} .'/lib';
    $PROVE_PROG = '/usr/bin/prove';
}

###----------------------------------------------------------------###

__PACKAGE__->navigate;

sub main_file_print {
    return \ qq {
        <h1>Run t/tests <span style=font-size:smaller>(<a href=[% scri
+pt_name %]?test=all>Run All</a>)</span></h1>
        [% rows = [];
           FOREACH dir IN files.keys.sort ;
             rows.push("<b><a href=\$script_name?test=\${dir.uri}>\${d
+ir.html}</a></b><br>");
             FOREACH file IN files.\$dir ;
               rows.push("&nbsp;&nbsp;&nbsp;&nbsp;<a href=\$script_nam
+e?test=\${dir.uri}/\${file.uri}>\${file.html}</a><br>");
             END;
           END;
           cols = 4;
           n_per_col = rows.size / cols;
           IF n_per_col - n_per_col.int;  n_per_col = n_per_col.int + 
+1; END;
           FOREACH j = [0 .. cols - 1] %]
             <div style="float:left; width:24%">
             [% min = j * n_per_col;
                max = min + n_per_col - 1;
                IF max > rows.max; max = rows.max; END;
                FOREACH i IN [min .. max]
                rows.\$i;
                END %]
             </div>
        [% END %]
    };
}

sub main_hash_swap {
    my $self = shift;
    my $dir  = $BASE_DIR;
    require File::Find;
    my $files = {};
    File::Find::find(sub {
        return if -d;
        return if $File::Find::name !~ m|^\Q$dir\E/(.+)/(.+\.t)$|;
        $files->{$1}->{$2} = 1;
    }, $dir);
    $files->{$_} = [sort keys %{$files->{$_}}] foreach keys %$files;

    return {files => $files};
}

sub main_info_complete {
    my $self = shift;
    my $file = $self->form->{'test'} || return 0;
    return 0 if $file =~ /\.\./;
    return 0 if $file !~ /^([\w\.\/\-]+)$/;
    $file = $1;
    $file =~ s|^/+||;

    my $dir  = $BASE_DIR;
    return 0 if ! -e "$dir/$file" && lc $file ne 'all';

    $self->stash->{'test'} = $self->form->{'test'} = $file;
    $self->append_path('_run');
    return 1;
}

sub _run_file_print {
    return \ qq {
        <h1>Test - [% test %]</h1><br>
    };
}

sub _run_info_complete { 0 }

sub _run_post_print {
    my $self = shift;
    my $file = $self->stash->{'test'} || die "Missing test";
    my $exe  = $PROVE_PROG;
    $file = '' if lc($file) eq 'all';
    open(my $fh, "$exe -v -I$LIB_DIR -r $BASE_DIR/$file 2>&1 |") || do
+ { debug "Couldn't exec", $exe, $!; die "Couldn't exec: $!" };

    my $r;
    if ($self->cgix->is_mod_perl_2) {
        $r = $self->cgix->apache_request;
    } else {
        $| = 1;
    }

    print "<span style=\"font-family:monospace;color:green\">\n";
    while (defined(my $line = <$fh>)) {
        $line =~ s/\s+$//;
        if ($line =~ /^\s*not/) {
            $line = "<span style=color:red>$line</span>";
        } elsif ($line !~ /^\s*ok/) {
            $line = "<span style=color:blue>$line</span>";
        }
        print $line."<br>\n";
        $r->rflush if $r;
    }
    print "</span>\n";
}
[download]

You might want to take a look at Test::TAP::Model and friends to present the test result. My local Module::Build subclass has:

sub _do_action_with_tap_model {
    my ( $self, $action ) = @_;
    require Test::TAP::Model::Visual;
    require Test::TAP::HTMLMatrix;
    require File::Path;
    File::Path::mkpath( 'html/t' );
    my $model = Test::TAP::Model::Visual->new 
        or croak "could not make Test::TAP::Model::Visual";
    {   
        require Test::Harness;
        no warnings 'redefine';
        my $original = \&Test::Harness::runtests;
        local *Test::Harness::runtests = sub {
            local *Test::Harness::runtests = $original;
            $model->run_tests( @_ )
        };
        print "starting $action with html test results\n";
        $self->$action( @_ );
        print "finished $action with html test results\n";
    }
    my $html_matrix = Test::TAP::HTMLMatrix->new( $model ) 
        or croak "could not make Test::TAP::HTMLMatrix";
    open( my $fh, '>', 'html/t/index.html' ) or croak "open failed ($!
+)";
    print $fh $html_matrix->html or croak "print failed ($!)";
    close $fh or croak "close failed ($!)";
    print "test results written to html/t/index.html\n";
}

sub ACTION_testhtml {
    my $self = shift;
    $self->_do_action_with_tap_model( 'ACTION_test' );
}

sub ACTION_smoke {
    my $self = shift;
    $self->_do_action_with_tap_model( 'ACTION_testcover' );
}
[download]

While allows me to do things like ./Build testhtml to get pretty HTML results in html/t.