$foo = ':{"'
$foo =~ s/([:,{])(.)/$1 $2/g;
[download]

The first match of the regex matches :{, and then the regex engine continues looking after that match, but the only thing there is ", which does not match your regex, which expects two characters.

This works (although not yet tested on a lot of different inputs): s/(?<=[:,{])(?=.)/ /g (using Zero-Width Lookaround Assertions)

occurrences of left square bracket, colon and left brace

Left square brackets, or commas? You've got [:,{]

Of course, if you're cleaning up JSON, it might be better to just round trip it through a module that can pretty-print it?

The following regex:

$foo =~ s/([:,{])(.)/$1 $2/g;
[download]

If you want the regex engine to repeatedly match each of the input characters, please remove the (.) part:

$foo =~ s/([:,{])/$1 /g;
[download]

  DB<1> $foo = ':{"';

  DB<2> $foo =~ s/([:,{])/$1 /g;

  DB<3> print $foo
: { "
[download]

Hello talexb,

From the end of perlop#Regexp-Quote-Like-Operators:

Occasionally, you can't use just a /g to get all the changes to occur that you might want. Here are two common cases:

    # put commas in the right places in an integer
    1 while s/(\d)(\d\d\d)(?!\d)/$1,$2/g;

    # expand tabs to 8-column spacing
    1 while s/\t+/' ' x (length($&)*8 - length($`)%8)/e;
[download]

(Note that the /g modifier in the first example isn’t actually needed.) You can adapt this approach to your requirements:

my $foo = ':{,"';
1 while $foo =~ s/([:,{])(?! )(.)/$1 $2/;
print ">$foo<\n";
[download]

Output:

19:22 >perl 1872_SoPW.pl
>: { , "<

19:22 >
[download]

Hope that’s of interest,

$foo =~ s/([:,{])/$1 /g;
[download]

missing ';' on first line.

Ugh .. thanks. Copy and pasted from the debugger.

Alex / talexb / Toronto

Thanks PJ. We owe you so much. Groklaw -- RIP -- 2003 to 2013.

for step through use rxrx

$foo = ':{"';
$foo =~ s/([:,{])(.)/$1 $2/g;
print "'$foo'\n";
[download]

If you just want a space after each of those, but not if it's the last char in a string:

1 while $foo =~ s/([:,{])([^ ])/$1 $2/g; # [^ ] is "not space"
[download]

If you want it after the last char in a string, you'll need something like:

1 while $foo =~ s/([:,{])([^ ]|$)/$1 $2/g;
[download]

But no while-loop at all is needed (and no captures) if lookarounds are used. (I'm substituting  '.' rather than a space in the examples below for greater clarity — I hope.)

Inserting something after each character in the class including when it's at the end of the string:

c:\@Work\Perl\monks>perl -wMstrict -le
"my @foos = (':X,{X', ':X,{');
 ;;
 for my $foo (@foos) {
   printf qq{'$foo' -> };
   $foo =~ s( (?<= [:,{]) ){.}xmsg;
   print qq{'$foo'};
   }
"
':X,{X' -> ':.X,.{.X'
':X,{' -> ':.X,.{.'
[download]

Inserting something after each character in the class except when it's at the end of the string:

c:\@Work\Perl\monks>perl -wMstrict -le
"my @foos = (':X,{X', ':X,{');
 ;;
 for my $foo (@foos) {
   printf qq{'$foo' -> };
   $foo =~ s( (?<= [:,{]) (?= .) ){.}xmsg;
   print qq{'$foo'};
   }
"
':X,{X' -> ':.X,.{.X'
':X,{' -> ':.X,.{'
[download]

(These examples work with Perl 5.8. Note that with the Perl 5.10+ regex  \K operator, the  (?<= [:,{]) terms in both examples can simplify to  [:,{] \K instead.)

Update: Note also that in all cases  (?! \z) can perhaps better express the "except at the end of the string" requirement than  (?= .) — and may even be slightly faster!

---

Give a man a fish:  <%-{-{-{-<