You can use grouping with the or operator within the regex, combined with word boundaries:

use warnings;
use strict;
use feature 'say';

my @strings = (
    "Bob said hello\n",
    "Alice doesn't like Chris\n",
    "This line won't match\n"
);

for (@strings){
    say "yay!" if /(?:\bAlice\b|\bBob\b|\bChris\b)/;
}
[download]

That says:

/
  (?:         # group, but don't capture
    \bAlice\b # capture Alice, if it is standalone
    |         # or
    \bBob\b   # same as Alice above
    |         # or
    \bChris\b # same as Alice and Bob
  )           # end grouping
/
[download]

Thank you, I will try it!

ack is simple to install, via CPAN, package or simple download. Read How

For work (Windows) I use docfetcher (although it is ancient).

For that onetime search: find . -name '*.htm*' -exec grep -i -e foo -e bar {} /dev/null \; (search for foo or bar inside .html and .htm files...)

I must do it alone, it is a task for university, I wish I could've used it... I don't at all know how my script should look like in order for me to be able to extract the matches from the current directory into a new one..

Hello Staralfur,

Another alternative is to use find with multiple parameters and traverse through your directories. But notice that on some systems (such as Cygwin), parentheses are necessary to make the set of extensions inclusive: my @files = `find $path \( -name '*.c' -o -name '*.txt'\)`;.

Sample of script (WRONG see bellow Update2 and Update3):

#!/usr/bin/perl
use strict;
use warnings;
use Data::Dumper;

my $path = shift || '.';

print Dumper traverse($path);

sub traverse {
    my ($path) = @_;

    my @files = `find $path -name '*.c' -o -name '*.txt'`;

    return if not -d $path;
    opendir my $dh, $path or die;
    while (my $sub = readdir $dh) {
        next if $sub eq '.' or $sub eq '..';
        traverse("$path/$sub");
    }
    close $dh;
    chomp @files;
    return \@files;
}

__DATA__

$ perl file.pl
$VAR1 = [
          './counts.txt',
          './file.txt',
          './sample.c',
          './testDir/anotherSample.c',
          './test.txt'
        ];
[download]

But to be 100% honest, I think I would have gone also with stevieb, more generic on OS system. But maybe you can come up with something different.

Update: Combining stevieb solution and File::Find:

#!/usr/bin/perl
use strict;
use warnings;
use File::Find;
use Data::Dumper;

my @dirs = @ARGV ? @ARGV : ('.');

my @list;
find( sub{
    push @list, $File::Find::name if -f $_
    && $_ =~ /(?:\btest\b|\bsample\b|\bChris\b)/ }, @dirs );

print Dumper \@list;

__DATA__

$ perl file.pl
$VAR1 = [
          './test.pl~',
          './sample.c',
          './test.txt~',
          './test.pl',
          './test.txt'
        ];
[download]

Update2: Combining stevieb solution and recursive search on directories:

#!/usr/bin/perl
use strict;
use warnings;
use Data::Dumper;

my @files;
my $path = shift || '.';
print Dumper traverse($path);

sub traverse {
    my ($path) = @_;

    return if not -d $path;
    opendir my $dh, $path or die;
    while (my $sub = readdir $dh) {
        next if $sub eq '.' or $sub eq '..';
    push @files, "$path/$sub"
        if ("$path/$sub" =~ /(?:\btest\b|\banotherSample\b|\bsample\b)
+/);
    traverse("$path/$sub");
    }
    close $dh;
    return \@files;
}

__DATA__

$ perl file.pl
$VAR1 = [
          './test.pl~',
          './sample.c',
          './test.txt~',
          './testDir/anotherSample.c',
          './test.pl',
          './test.txt'
        ];
[download]

Update3: :Another alternative is to use find with multiple parameters and traverse through your directories. But notice that on some systems (such as Cygwin), parentheses are necessary to make the set of extensions inclusive: my @files = `find $path \( -name '*.c' -o -name '*.txt'\)`;.

#!/usr/bin/perl
use strict;
use warnings;
use Data::Dumper;

my $path = shift || '.';

my @files = `find $path -name '*.c' -o -name '*.txt'`;

chomp @files;
print Dumper \@files;

__DATA__

$ perl file.pl
$VAR1 = [
          './test.pl~',
          './sample.c',
          './test.txt~',
          './testDir/anotherSample.c',
          './test.pl',
          './test.txt'
        ];
[download]

Hope this helps.

"...it seems to be the easiest way..."

Who knows. Consider File::Find::Rule:

# untested
use File::Find::Rule;
my @files = File::Find::Rule->file()
                            ->name('*.html')
                            ->grep($pattern)
                            ->in($dir);
[download]

Regards, Karl