Re^2: P6: Beginning grammar

in reply to Re: P6: Beginning grammar
in thread P6: Beginning grammar

( Moritz: Thanks. Thursday, I grabbed a copy of the book and moved to the latest rakudo release. I didn't find the .perl method yet; so I'll just salivate for a while more. I will look again at the book--that was helpful. )

This is going slow as I have little time (and lots of ignorance) but I will keep scratching away.

#!/home/rir/rakudo/parrot_install/bin/perl6

{
    grammar Calc {
        token TOP { <expression> }
        rule expression { <lhs> <op> <rhs> }
        token lhs { <numeric> }
        token rhs { <numeric> }
        token numeric { \d+[\.\d*]? }
        token op { '-' | '+' | '*' | '/' | 'x' }
    }

    class Calc::Actions {
        method TOP($/) { make $<expression>.ast }
        method expression($/) { make eval "$/<lhs> $/<op>.ast() $/<rhs
+>" }
        method lhs($/) { make $/ }
        method rhs($/) { make $/ }
        method numeric($/) { make $/ }
        method op($/) { if ( $/ eq 'x') { make '*'; } else {make $/; }
+ }
    }

    my $m = Calc.parse( "8.8 x 5.0 - 2",  :actions( Calc::Actions));
    die "dying no match"  unless  $m;
    say "$m<expression> =  $m.ast()";
}
[download]

Ok, I have retrenched. I grabbed Rakudo's/Pug's spectest and found some grammars that compile out of the box. The above is built up from t/spec/S05-grammarr/action-stubs.t . (Running spectest was less onerous than I expected.)

The above is meant to model a cheap calculator.

Questions:

Is the string eval reasonable here?
Can the expression rule be handled without the separate naming of the lhs and rhs? Is there a way to access each numeric in something like:
```
   rule expression { <numeric> <op> <numeric> }
[download]
```
The above can easily be extended by changing the rhs token line to
```
token rhs { <numeric> | <expression> }
[download]
```
But this destroys the calculator's left associativity and equal precedence. I suppose this could be addressed by changing the rule expression line to:
```
   rule expression { <lhs> ( <op> <rhs> )+ }
[download]
```
but I'm getting lost here.

Be well,
rir

Comment on Re^2: P6: Beginning grammar Select or Download Code

Replies are listed 'Best First'.
Re^3: P6: Beginning grammar by moritz (Cardinal) on Jun 08, 2010 at 06:47 UTC
I forgot to mention, some of the features of Match objects need the latest Rakudo development version, the release lags behind. Is the string eval reasonable here? Yes, though you can easily avoid it with a hash: `my %actions = '' => { $^a $^b }, '/' => { $^a / $^b }, '+' => { $^a + $^b }, '-' => { $^a - $^b }; ... make %actions{$<op>.ast}.(\|$/<lhs rhs>)` [download] Again, hash slices on Match objects likely require a new version of Rakudo built from source. Can the expression rule be handled without the separate naming of the lhs and rhs? Is there a way to access each numeric in something like: `rule expression { <numeric> <op> <numeric> }` First of all you can do the renaming inline: `rule expression { <lhs=.numeric> <op> <rhs=.numeric> }` [download] I'd prefer this solution for clarity. However you can also use `<numeric>` twice in the same regex, in which case `$<numeric>` becomes and array. Then you can access the left and right side as `$<numeric>[0]` and `$<numeric>[1]`. `rule expression { <lhs> ( <op> <rhs> )+ }` The corresponding action method might look like this: `method numeric($/) { make +$/ } # ^ convert to a number # propagate the number as the AST: method lhs($/) { make $<numeric>.ast } method rhs($/) { make $<numeric>.ast } method expression($/) { my $value = $<lhs>.ast; # iterate over all matches of the first (...) group for $0.list -> $m { $value = %actions{$m<op>.ast}.($value, $m<rhs>.ast); } make $value; }` [download] I hope this helps. Update: Here's a complete, working example that also passes the action down as an AST: use v6; grammar Calc { token TOP { <expression> } rule expression { <lhs=.numeric> ( <op> <rhs=.numeric> )* } token numeric { \d+[\.\d]? } token op { '-' \| '+' \| '' \| '/' \| 'x' } } my %actions = '' => { $^a $^b }, 'x' => { $^a * $^b }, '/' => { $^a / $^b }, '+' => { $^a + $^b }, '-' => { $^a - $^b }; class Calc::Actions { method TOP($/) { make $<expression>.ast } method expression($/) { my $value = $<lhs>.ast; for $0.list -> $m { $value = $m<op>.ast.($value, $m<rhs>.ast); } make $value; } method numeric($/) { make +$/ } method op($/) { make %actions{$/} } } my $m = Calc.parse( "8.8 x 5.0 - 2", :actions( Calc::Actions)); die "dying no match" unless $m; say "$m<expression> = $m.ast()"; # vim: ft=perl6 [download] Perl 6 - links to (nearly) everything that is Perl 6.	[reply] [d/l] [select]

Replies are listed 'Best First'.

Re^3: P6: Beginning grammar
by moritz (Cardinal) on Jun 08, 2010 at 06:47 UTC

I forgot to mention, some of the features of Match objects need the latest Rakudo development version, the release lags behind.

Is the string eval reasonable here?

Yes, though you can easily avoid it with a hash:

my %actions = 
   '*' => { $^a * $^b },
   '/' => { $^a / $^b },
   '+' => { $^a + $^b },
   '-' => { $^a - $^b };
...
make %actions{$<op>.ast}.(|$/<lhs rhs>)
[download]

Again, hash slices on Match objects likely require a new version of Rakudo built from source.

Can the expression rule be handled without the separate naming of the lhs and rhs? Is there a way to access each numeric in something like: rule expression { <numeric> <op> <numeric> }

First of all you can do the renaming inline:

rule expression { <lhs=.numeric> <op> <rhs=.numeric> }
[download]

I'd prefer this solution for clarity. However you can also use <numeric> twice in the same regex, in which case $<numeric> becomes and array. Then you can access the left and right side as $<numeric>[0] and $<numeric>[1].

rule expression { <lhs> ( <op> <rhs> )+ }

The corresponding action method might look like this:

method numeric($/) { make +$/ }
#                         ^  convert to a number

# propagate the number as the AST:
method lhs($/) { make $<numeric>.ast }
method rhs($/) { make $<numeric>.ast }


method expression($/) {
   my $value = $<lhs>.ast;

   # iterate over all matches of the first (...) group
   for $0.list -> $m {
       $value = %actions{$m<op>.ast}.($value, $m<rhs>.ast);
   }
   make $value;
}
[download]

I hope this helps.

Update:

Here's a complete, working example that also passes the action down as an AST:

use v6;
grammar Calc {
    token TOP { <expression> }
    rule expression { <lhs=.numeric> ( <op> <rhs=.numeric> )* }
    token numeric { \d+[\.\d*]? }
    token op { '-' | '+' | '*' | '/' | 'x' }
}

my %actions =
    '*' => { $^a * $^b },
    'x' => { $^a * $^b },
    '/' => { $^a / $^b },
    '+' => { $^a + $^b },
    '-' => { $^a - $^b };

class Calc::Actions {
    method TOP($/) { make $<expression>.ast }
    method expression($/) {
        my $value = $<lhs>.ast;
        for $0.list -> $m {
            $value = $m<op>.ast.($value, $m<rhs>.ast);
        }
        make $value;
    }
    method numeric($/) { make +$/ }
    method op($/) { make %actions{$/} }
}

my $m = Calc.parse( "8.8 x 5.0 - 2",  :actions( Calc::Actions));
die "dying no match"  unless  $m;
say "$m<expression> =  $m.ast()";

# vim: ft=perl6
[download]

Perl 6 - links to (nearly) everything that is Perl 6.

[reply]
[d/l]
[select]

In Section Seekers of Perl Wisdom