Re^3: Algorithm For Uninstalling Dependencies

in reply to Re^2: Algorithm For Uninstalling Dependencies
in thread Algorithm For Uninstalling Dependencies

Oh, I think I see what you mean now..

Here is something that I think does what you want:

use strict;

my %graph = (
    FOO   => [qw/BAR BLAH ASDF/],
    BAR   => [qw/LA/],
    BLAH  => [qw/XYZ/],
    ASDF  => [qw/OOOOO/],
    LA    => [],
    XYZ   => [qw/LA/],
    OOOOO => []
);

my %reversegraph;
for my $x (keys %graph) {
  for my $y (@{ $graph{$x} }) {
    push @{$reversegraph{$y}}, $x;
  } 
}

{
  my %seen;
  my %onstack;
  my @list;

  sub how_to_uninstall {
      my $target = shift;
      (@list, %seen, %onstack) = ();

      _traverse(\%reversegraph, $target);
      my @dependedontarget = @list;

      (@list, %seen, %onstack) = ();
      for my $v (@dependedontarget) {
          _traverse(\%graph, $v) unless $seen{$v};
      }

      return @list;
  } 

  sub _traverse {
      my ($G,$x) = @_;
      $seen{$x} = $onstack{$x} = 1;
      for my $y (@{$G->{$x}}) {
          die "cyclic!" if $onstack{$y};    # back edge
          _traverse($G,$y) unless $seen{$y};
      }
      push @list, $x;
      $onstack{$x} = 0;
  }
}
my @order = how_to_uninstall('BLAH');
print "@order\n";

__OUTPUT__
LA BAR XYZ BLAH OOOOO ASDF FOO
[download]

You do a DFS from the target, following edges backwards. The resulting list will tell you all of the items that depend on the target. These are all the items that we know must be removed if the target is to be removed (according to your rules). The fact that we used DFS here doesn't really matter, we just need a list of all vertices that can reach the target.

Now we have a list of items that must be removed. Before removing any item, we must first remove all of its dependents. This where the topological sort happens. Doing a DFS (following edges forward) from some item X results in a topological sorting of the items that must be removed if you want to remove X. So we can just do a DFS from each of vertices in that list. We re-use the %seen array so that these multiple DFS calls don't repeat (similar to how you would do topological sort on an entire graph, by starting new DFSes until everything has been seen).

On a side note, it seems slightly odd that you would remove all of FOO and all of its dependencies as a result of removing BLAH. What if BAR or XYZ are required elsewhere? Are there more conditions than are captured in this small example?

blokhead

In Section Seekers of Perl Wisdom