in reply to Context: compile-time vs. run-time
At compile-time, the context is set to one of the following:
- Void
- Scalar
- List
- From subroutine's caller
An operator cannot control context at run-time. It cannot be any other way because operators are executed after their operands. Consider
@x = ( f(), g(), h() );
There are four ops on the RHS of the assignment. In the order they are called, they are:
- entersub(f): Calls f and leaves result on the stack
- entersub(g): Calls g and leaves result on the stack
- entersub(h): Calls h and leaves result on the stack
- list: Filters all but the last element off the stack in scalar context. No-op otherwise
The list operator never has a chance to control the context of its operands since they've already been evaluated by the time the list operator is evaluated.
That is actually the source of a known bug in Perl. What follows explains it. At compile-time, the contexts in which the above operators are evaluated are set as follows:
- entersub(f): List
- entersub(g): List
- entersub(h): List
- list: List [*]
And it works well. It also works well in scalar context:
$x = ( f(), g(), h() );
- entersub(f): Void
- entersub(g): Void
- entersub(h): Scalar
- list: Scalar
And in void context:
( f(), g(), h() ); 1;
- entersub(f): Void
- entersub(g): Void
- entersub(h): Void
- list: Void
And now we're left with the fourth case:
sub { ( f(), g(), h() ) }
- entersub(f): From subroutine's caller
- entersub(g): From subroutine's caller
- entersub(h): From subroutine's caller
- list: From subroutine's caller
If we call the subroutine as
@x = sub { ( f(), g(), h() ) }->();
then all's fine:
- entersub(f): From subroutine's caller: List
- entersub(g): From subroutine's caller: List
- entersub(h): From subroutine's caller: List
- list: From subroutine's caller: List
But if we call the subroutine as
$x = sub { ( f(), g(), h() ) }->();
we have a bug!
- entersub(f): From subroutine's caller: Scalar: should be void!
- entersub(g): From subroutine's caller: Scalar: should be void!
- entersub(h): From subroutine's caller: Scalar
- list: From subroutine's caller: Scalar
Some code to support what I said:
use strict; use warnings; sub cx { print !defined(wantarray()) ? 'v' : !wantarray() ? 's' : 'l'; } my ($x, @x); print('v: '); ( cx(), cx(), cx() ) ; print("\n"); print('cv: '); sub { ( cx(), cx(), cx() ) }->(); print("\n\n"); print('s: '); $x = ( cx(), cx(), cx() ) ; print("\n"); print('cs: '); $x = sub { ( cx(), cx(), cx() ) }->(); print("\n\n"); print('l: '); @x = ( cx(), cx(), cx() ) ; print("\n"); print('cl: '); @x = sub { ( cx(), cx(), cx() ) }->(); print("\n");
v: vvv cv: vvv s: vvs \ mismatch cs: sss / l: lll cl: lll
A practical difference:
use strict; use warnings; my $x; $x = ( 'abc', 'def' ) ; # Warns $x = sub { ( 'abc', 'def' ) }->(); # Doesn't warn
Useless use of a constant in void context at line 5.
* — A list op in list context is subsequently optimized away since it's a no-op there. This does not affect the results.