This seems to get closed to the required output:

Updated: Corrected fencepost-ish error.

Update2: Added a second pass to condense it a bit.

#! perl -slw
use strict;

( my $input = do{ local $/; <DATA> } ) =~ tr[\n][]d;

my $tab = 0;
$input =~ s[([()])]{
    $tab-- if $1 eq ')';
    my $modified = "\n" . ( "    " x $tab ) . $1;
    $tab++ if $1 eq '(';
    $modified;
}ge;
$input =~ s[\n\s+\)][)]g;

print $input;

__DATA__
(&(&(&(& (mailnickname=*) (| (&(objectCategory=person)(objectClass=use
+r)(!(homeM
DB=*))(!(msExchHomeServerName=*)))(&(objectCategory=person)(objectClas
+s=user)(|
(homeMDB=*)(msExchHomeServerName=*)))(&(objectCategory=person)(objectC
+lass=cont
act))(objectCategory=group)(objectCategory=publicFolder)(objectCategor
+y=msExchD
ynamicDistributionList) )))(objectCategory=contact)(proxyAddresses=smt
+p:*exampl
e.com)))
[download]

Yields:

P:\test>junk1

(&
    (&
        (&
            (&
                (mailnickname=*)
                (|
                    (&
                        (objectCategory=person)
                        (objectClass=user)
                        (!
                            (homeMDB=*))
                        (!
                            (msExchHomeServerName=*)))
                    (&
                        (objectCategory=person)
                        (objectClass=user)
                        (|
                            (homeMDB=*)
                            (msExchHomeServerName=*)))
                    (&
                        (objectCategory=person)
                        (objectClass=contact))
                    (objectCategory=group)
                    (objectCategory=publicFolder)
                    (objectCategory=msExchDynamicDistributionList) )))
        (objectCategory=contact)
        (proxyAddresses=smtp:*example.com))
)
[download]

Very interesting! I have just some difficulties in reading that s/// operator. Could you please explain?

Thanks for posting!

Ciao!
--bronto

---

In theory, there is no difference between theory and practice. In practice, there is.

Sure.

my $tab = 0; ## Number of 'tabs' to insert starts at zero
$input =~ s[
    (          ## Capture to $1
       [()]    ## All open or close parens
    )
]{  ## /e-xecute turns the second half into a code block.
    ## Decrement teh tab count if this is a close paren
    $tab-- if $1 eq ')';

    ## Insert a newline + $tab tabs before the paren (open or close)
    my $modified = "\n" . ( "    " x $tab ) . $1;

    ## Increment the tab count if this is an open paren
    $tab++ if $1 eq '(';

    ## And 'return' the modified text for substitution
    $modified;
}xge;

## Late addition:
## Second pass strips out any 'lone' close parens
## to compact the results a little.
$input =~ s[\n\s+\)][)]g;
[download]

---

Examine what is said, not who speaks -- Silence betokens consent -- Love the truth but pardon error.

Lingua non convalesco, consenesco et abolesco. -- Rule 1 has a caveat! -- Who broke the cabal?

"Science is about questioning the status quo. Questioning authority".

In the absence of evidence, opinion is indistinguishable from prejudice.

What about using a FSA based parser?

#!/usr/bin/perl
use strict;
use warnings;
use Text::Diff;

{
my $INDENT_STEP=4;
sub indenter {
    my ($expr)=@_;

    my $indent=0;
    my $result='';
    pos($expr)=undef;
    while(1) {
        if ($expr =~ m{\G \s* ( \( [&|!] )}smxcg) {
            # combinatore: print, newline, inc indent
            $result.=(' 'x$indent)."$1\n";
            $indent+=$INDENT_STEP;
        }
        elsif ($expr =~ m{\G \s* ( \( [^)=]+ = [^)]+ \) )}smxcg) {
            # test: print, newline
            $result.=(' 'x$indent)."$1\n";
        }
        elsif ($expr =~ m{\G \s* ( \) )}smxcg) {
            # fine combinatore: dec intert, print, newline
            $indent-=$INDENT_STEP;
            $result.=(' 'x$indent)."$1\n";
        }
        else {
            last;
        }
    }
    return $result;
}
}

my $expr=q{(&(&(&(& (mailnickname=*) (| (&(objectCategory=person)(obje
+ctClass=user)(!(homeMDB=*))(!(msExchHomeServerName=*)))(&(objectCateg
+ory=person)(objectClass=user)(|(homeMDB=*)(msExchHomeServerName=*)))(
+&(objectCategory=person)(objectClass=contact))(objectCategory=group)(
+objectCategory=publicFolder)(objectCategory=msExchDynamicDistribution
+List) )))(objectCategory=contact)(proxyAddresses=smtp:*example.com)))
+};

my $expected=<<'END_EXPECTED';
(&
    (&
        (&
            (&
                (mailnickname=*)
                (|
                    (&
                        (objectCategory=person)
                        (objectClass=user)
                        (!
                            (homeMDB=*)
                        )
                        (!
                            (msExchHomeServerName=*)
                        )
                    )
                    (&
                        (objectCategory=person)
                        (objectClass=user)
                        (|
                            (homeMDB=*)
                            (msExchHomeServerName=*)
                        )
                    )
                    (&
                        (objectCategory=person)
                        (objectClass=contact)
                    )
                    (objectCategory=group)
                    (objectCategory=publicFolder)
                    (objectCategory=msExchDynamicDistributionList)
                )
            )
        )
        (objectCategory=contact)
        (proxyAddresses=smtp:*example.com)
    )
)
END_EXPECTED

my $ret=indenter($expr);
print "ok\n" if $ret eq $expected;
print diff \$ret,\$expected, {
    STYLE => 'Unified',
};
[download]

-- 
        dakkar - Mobilis in mobile