If your running Win32 then Win32::ChangeNotify makes this very easy.

#! perl -slw
use strict;
use Win32::ChangeNotify;

my $path = 'p:\test';

my $notify = Win32::ChangeNotify->new( $path, 0, 'FILE_NAME' );

my %last; @last{ glob $path . '/*' } = ();

while( 1 ) {
    print('Nothing changed'), next
        unless $notify->wait( 10_000 ); # Check every 10 seconds
    $notify->reset;
    print $/, 'Something changed';
    my @files = glob $path . '/*';
    if( @files < scalar keys %last ) {
        delete @last{ @files };
        print 'These files where deleted: ';
        print for keys %last;
            print'';
    }
    elsif( @files > scalar keys %last ) {
        my %temp;
        @temp{ @files } = ();
        delete @temp{ keys %last };
        print 'These files where created: ';
        print for keys %temp;
            print'';
    }
    else {
        print "A non-deletion or creation change occured";
    }
    undef %last;
    @last{ @files } = ();
}
__END__
P:\test>changenotify
Nothing changed
Nothing changed

Something changed
These files where created:
p:\test/fred

Nothing changed
Nothing changed

Something changed
These files where deleted:
p:\test/fred

Nothing changed
Nothing changed
Nothing changed
Nothing changed
[download]

You'll need control-break rather than ^C to interupt this script.

To extending this to monitor the whole subtree, change the 0 in the new() call to 1, though you'll need some extra work to find out what changed where.

I'm not aware of a similar mechanism under *nix.

The comment on the

unless $notify->wait( 10_000 );
[download]

line is misleading. The script doesn't check for changes every ten seconds. It waits for a change for 10 seconds, prints the "Nothing changed" message and goes back waiting. Any changes in the directories are noted immediately.

Jenda
Always code as if the guy who ends up maintaining your code will be a violent psychopath who knows where you live.
   -- Rick Osborne

Edit by castaway: Closed small tag in signature

Good point. That was badly worded.

---

Examine what is said, not who speaks.
"Efficiency is intelligent laziness." -David Dunham
"When I'm working on a problem, I never think about beauty. I think only how to solve the problem. But when I have finished, if the solution is not beautiful, I know it is wrong." -Richard Buckminster Fuller
If I understand your problem, I can solve it! Of course, the same can be said for you.

#!/usr/bin/perl

use strict;
use DB_File;

my $base    = '/some/dir';     # dir to check
my $data    = '/some/file.db'; # file name cache
my $sleep   = 100;             # how long to sleep for
my $maxtime = 86400;           # max time before key removal

while (1) {
#
# we need to tie and untie each time just to be safe due
# to file caching and flushing, which sometimes doesnt 
# happen untill the file has been untied. 
# If another monk can help here that would be nice.
#
   tie(my %files, 'DB_File', $data, O_RDWR, 0644)
      or die "Cant tie $data: $!\n";

   opendir(BASE, $base) or die "Cant open dir $base: $!\n";
   for ( grep(!/^\./, readdir BASE) ) { # avoid . and .. :)
      if ( $files{$_} ) {
         $files{$_} = time();

      } else {
         do_something();
         $files{$_} = time();
      }
   }
   closedir(BASE);

   for ( keys %files ) {
# remove the file if it hasnt been around for a week
      delete($files{$_}) if ($files{$_} >= $maxtime);
   }
   untie(%files);

   sleep $sleep;
}
[download]

use perl;

If you know what the files will be (example, they are uploaded by a script so the filename will always be the same) you could do something like:

while (1)
 {
   if (-e "/my/dir/filename.dat")
    {
      do_something_now();
    }
 }
[download]

my $items_in_dir = @Dircontent;
if ($items_in_dir > 2) ..
[download]

if (scalar(@Dircontent) > 2) ..
[download]

This:

my $items_in_dir = @Dircontent;
if ($items_in_dir > 2) ..
[download]

won't work if some smart alec decides to create a subdir in your drop area. try using -f

TISMTOWTDI:

use strict;
use warnings;

sub scandir
{
    my $dir = shift;
    my $fileProcessor = shift;

    opendir (DIR, $dir) or die "Cannot open $dir: $!\n";
    for (readdir DIR)
    {
        if ( -f )
        {
            &$fileProcessor($_);
        }
    }
    close DIR;
}


sub do_something
{
    my $filename = shift;
    print "got file: $filename\n";
}

sub do_something_else
{
    my $filename = shift;
    print "got another file: $filename\n";
}


scandir('.',\&do_something);
scandir('.',\&do_something_else);
[download]

Liz

Makeshifts last the longest.

if(scalar(@Dircontent) > 2) {
     # do stuff
}
[download]

Of course, if someone copies a file there and is still dropping it while your loop runs in the cycle you may see issues with truncating data. You should also build in tests to see if the file is done being written to. I assume you are moving the file to proccess it not just to move it.

-Waswas