sub explain {
        my $val = shift;
        print "Numeric value = ", 0+$val, "\n";
        print "String value = \"$val\"\n";
        print "Truth value = ", $val ? "true\n" : "false\n";
    }
[download]

    # explain("23skidoo");
    Numeric value = 23
    String value = "23skidoo"
    Truth value = true

    # explain(1_2_3);
    Numeric value = 123
    String value = "123"
    Truth value = true

    # explain("1_2_3");
    Numeric value = 1
    String value = "1_2_3"
    Truth value = true

    # explain("00");
    Numeric value = 0
    String value = "00"
    Truth value = true

    # explain("0");
    Numeric value = 0
    String value = "0"
    Truth value = false
    
    # explain(undef);
    Numeric value = 0
    String value = ""
    Truth value = false
[download]

[robin@robin robin]$ perl -wle 'print 0+"23skidoo"'
Argument "23skidoo" isn't numeric in addition (+) at -e line 1.
23
[download]

But the string "0 but true" is exempt from the warning:

[robin@robin bits & pieces]$ perl -wle 'print 23+"0 but true"'
23
[download]

References and typeglobs

Not all scalars are simple. Some are references. Let's try one:

    # explain([1,2,3]);
    Numeric value = 25616
    String value = "ARRAY(0x6410)"
    Truth value = true
[download]

The numeric value is just the memory address used to store the target of the reference. (25616 (base 10) is equal to 6410 (base 16).) That's handy, because it means you can compare two references with $ref1 == $ref2 to find out if they both refer to the same thing.

Some references are blessed, of course. Objects. We'll look at those in the next section. But there's another kind of special scalar - the typeglob. If you did much Perl programming back in the days of Perl 4 you'll certainly remember typeglobs, because they behave like references in some ways and Perl 4 didn't have proper references.

    my $foo = *bar;
    our $bar = "hello\n";
    our @bar = ("Hello again!\n");
    print $$foo, @$foo;
    explain($foo);
[download]

prints

    hello
    Hello again!
    Numeric value = 0
    String value = "*main::bar"
    Truth value = true
[download]

So the string value of a glob is just the fully-qualified name of the variable(s) it refers to, preceded by a star.

Objects

An object is just a blessed reference:

    # explain(bless {}, "SomePackage");
    Numeric value = 25616
    String value = "SomePackage=HASH(0x6410)"
    Truth value = true
[download]

That's just like an ordinary reference, except that the name of the package it's blessed into is added to the beginning of the string value.

So far, the golden rule for truth has been adhered to strictly. Even the most esoteric special scalars are false if they have a string value of "" or "0", and otherwise they're true. But it gets more complicated than that. You can use overloading to change the default behaviour of an object.

    explain(bless {}, "SomePackage");
    package SomePackage;
    use overload '""'   => sub {'string value'};
    use overload '0+'   => sub {23};
    use overload 'bool' => sub {""};
    use overload fallback => 1;
[download]

prints:

    Numeric value = 23
    String value = "string value"
    Truth value = false
[download]

So you see that each of the three type conversions can be specified separately, and they don't have to be consistent with one another. That's reminiscent of the special variable $!, which gives an error number when used numerically and an error message when used as a string.

You don't have to specify all three. Perl will work out the unspecified conversions based on the conversions that you do specify. Suppose that we delete the '0+' and bool lines from the code above:

    Numeric value = 0
    String value = "string value"
    Truth value = true
[download]

That's what you ought to expect: Perl is making the same conversions that it would for an ordinary string. Okay, so suppose we specify the string value and the numeric value. What would you expect the truth value to be in this example:

    explain(bless {}, "SomePackage");
    package SomePackage;
    use overload '""'   => sub {''};
    use overload '0+'   => sub {23};
    use overload fallback => 1;
[download]

The answer is surprising. The golden rule is broken!

    Numeric value = 23
    String value = ""
    Truth value = true
[download]

Even though the string value is "", Perl still considers it to be true! In fact, the numeric value (if it exists) is always used to determine truth when overloading is in effect. (Unless of course an explicit truth value is supplied as well using the 'bool' overload.) This is very strange, and there doesn't appear to be any good reason for it. Unfortunately if we fixed it then existing code would break, so we're probably stuck with it, at least until Perl 6.

Actually, it's even weirder than it looks. What about this?

    explain(bless {}, "SomePackage");
    package SomePackage;
    use overload '""'   => sub { '' };
    use overload '0+'   => sub {'00'};
    use overload fallback => 1;
[download]

Can you predict the truth value? The thing is, the golden rule is being used here, but in a very odd way. The numeric value has a string value of "00", and so it's false!

The truth value is determined by the string value of the numeric value. Wondrous strange!