#!/usr/bin/perl
use warnings;
use strict;
use Data::Dumper;

my %args = (profile => 'foo');
my %ta = %args{ grep exists $args{$_}, qw( profile user password ) };
print Dumper \%ta;
[download]

So you want to filter-in hash elements that have a defined value:

my %args = (profile => 'foo');
my %ta = map {defined($args{$_} ? ($_ => $args{$_}) : ()} qw(profile u
+ser password);
[download]

If a map iteration returns an empty list, nothing gets added to the recipient's list. I don't usually like making map behave like grep, but in this case it seems a reasonable fit.

grep behavior can be provided by map by adding a Boolean test and a conditional return value.

my @array = grep {COND} LIST;
my @array = map {COND ? $_ : ()} LIST
[download]

>  grep { $args{$_ } } keys %ta;

Will also delete all false values like 0 or "" . You rather want to test on definedness and not truth

This keys on a slice

>   keys %args{'profile', 'user', 'password'};

Is over complicated and doesn't make sense.

You obviously just want the list of keys directly

'profile', 'user', 'password'

But I concur with choroba that using exists right from the beginning is the cleanest way, since undef could be a legal value.

edit

There is - unfortunately - no "slice when exists" operator in Perl.

Otherwise (ab)using hashes for set operations like intersections would be trivial.

On a side note,

I was surprised that the following is even legal syntax. I only knew slicing lists with @

>  %args{'profile', 'user', 'password'};

Turns out it was introduced with 5.20 and returns a list of key/value pairs.

Cheers Rolf
_{(addicted to the Perl Programming Language :)
Wikisyntax for the Monastery}

Otherwise (ab)using hashes for set operations like intersections would be trivial.

Though off-topic here: Is there a common idiom for an intersection of two hash-sets? The first thing that comes to my mind is something like:

%a_b = map {exists $b{$_} ? ($_ => $b{$_}) : ()} keys %a;
[download]

Greetings,
-jo

$gryYup$d0ylprbpriprrYpkJl2xyl~rzg??P~5lp2hyl0p$

Hi

You might be interested in this older thread

Using hashes for set operations...

and this particular post

Re: Using hashes for set operations...

Cheers Rolf
_{(addicted to the Perl Programming Language :)
Wikisyntax for the Monastery}

G'day nysus,

"Is there a good, more perlish way of pulling this off?"

In the absence of any information about wanting to capture the deleted keys, I'd probably just do this:

delete @ta{grep !defined $ta{$_}, keys %ta};
[download]

I'm not sure if the way you've constructed %ta is really what you intended; however, with Perl 5.30.0 I get no errors or warnings:

$ perl -Mstrict -Mwarnings -E '
    my %args = (profile => "foo");
    my %ta = %args{qw{profile user password}};
    say "BEFORE:";
    say for keys %ta;
    delete @ta{grep !defined $ta{$_}, keys %ta};
    say "AFTER:";
    say for keys %ta;
'
BEFORE:
profile
password
user
AFTER:
profile
[download]

> with Perl 5.30.0 I get no errors or warnings

5.20.0 Delta: New slice syntax.

map{substr$_->[0],$_->[1]||0,1}[\*||{},3],[[]],[ref qr-1,-,-1],[{}],[sub{}^*ARGV,3]

Could you elaborate on the reason for providing that link.

LanX had already noted the new syntax ("... it was introduced with 5.20 ...") so I saw no reason to comment further in my post.

Not that you would have known, but I did check the information from a different source: https://perldoc.perl.org/5.30.0/perldata.html#Key%2fValue-Hash-Slices via https://perldoc.perl.org/5.30.0/functions/delete.html (link in second paragraph).

— Ken

... filter out undefined values ... [emphasis added]

My take is that keys with undefined values (either because non-existent or undef) are to be filtered out. One way:

c:\@Work\Perl\monks>perl -wMstrict -MData::Dump -le
"my %args = ('profile' => 'foo',  'xyzzy' => undef,  'status' => 0);
 my %ta =
   map { defined $args{$_} ? ($_ => $args{$_}) : () }
   qw(profile  password  xyzzy  status)
   ;
 dd 'filtered', \%ta;
 dd 'original', \%args;
"
("filtered", { profile => "foo", status => 0 })

("original", { profile => "foo", status => 0, xyzzy => undef })
[download]

Here a concise way for cleaning up afterwards:

 $h{$_} // delete $h{$_} for keys %h

Unfortunately the even shorter approach doesn't work with deleting aliases

$_ // delete $_ for values %h

Cheers Rolf
_{(addicted to the Perl Programming Language :)
Wikisyntax for the Monastery}

#!/usr/bin/perl

use strict; # https://perlmonks.org/?node_id=11117569
use warnings;

my %args = (profile => 'foo');

my %ta = %args{ grep defined $args{$_}, 'profile', 'user', 'password' 
+};

use Data::Dump 'dd'; dd \%ta;
[download]