Does this need to remain resident and sleeping, or could it just be a cron that kicks off at 15 minute intervals? On Windows you could hand it to the task scheduler.

This still has the issue of how to stop it running; it's inconvenient to always be manipulating crontabs or task scheduler entities. But if the script started out like this:

__PACKAGE__->run(@ARGV)
    if -e '/path/to/run-me.flag' && ! caller;

sub run {
    # ... the work goes here...
}
[download]

...you would prevent future runs from doing anything. This doesn't address an stopping an in-progress run, but I think you are probably trying to prevent the script from waking up again. With this approach you just touch a file into existence if you want the script to proceed when the cron picks it up again. If the file has been removed the script won't proceed. You wouldn't want to leave an impotent cron laying around forever but if it's just a matter of needing to prevent it running for a few hours or days once in awhile, this seems like a reasonable solution.

The following runs in Linux and reacts to signals as expected:

#!/usr/bin/perl
use warnings;
use strict;
use feature qw{ say };

local $SIG{USR1} = sub {
    say STDERR "Signal 1 caught.";
    alarm 0;
};

local $SIG{USR2} = sub {
    say STDERR "Bye!";
    exit
};

my $sum = 0;
while (1) {
    $sum += $_  for 1 .. 100;
    say $sum;

    say STDERR scalar localtime, " Sleeping...";
    sleep 10;

    say STDERR scalar localtime, " Ready!";
}
[download]

A sample session:

▏~ $ 11111522.pl &
[1] 28265
5050
Fri Jan 17 15:28:04 2020 Sleeping...
Fri Jan 17 15:28:14 2020 Ready!
10100
Fri Jan 17 15:28:14 2020 Sleeping...
▏~ $ kill -USR1 28265
Signal 1 caught.
Fri Jan 17 15:28:17 2020 Ready!
15150
Fri Jan 17 15:28:17 2020 Sleeping...
▏~ $ kill -USR2 28265
Bye!
[1]+  Done                    11111522.pl
▏~ $

> I gladly forgot most about Autosys after quitting $job - 1

Thank G*d you didn't write $job-- ! OO

... you wouldn't like the implications ... ;-)

Cheers Rolf
_{(addicted to the Perl Programming Language :)
Wikisyntax for the Monastery FootballPerl is like chess, only without the dice}

I have [a] [...] script that [...] sleeps [...] If I add an ALRM signal handler, the ALRM stops working

One problem is in the man page sleep(3), at least on Linux:

Bugs

sleep() may be implemented using SIGALRM; mixing calls to alarm(2) and sleep() is a bad idea.

Using longjmp(3) from a signal handler or modifying the handling of SIGALRM while sleeping will cause undefined results.

program keeps running!!!! Any thoughts?

Multiple exclamation marks ...

Alexander

Kill is not what you want, it seems to ignor $SIG{KILL}

(Win32) kill doesn't send a signal to the identified process like it does on Unix platforms. Instead kill($sig, $pid) terminates the process identified by $pid , and makes it exit immediately with exit status $sig . As in Unix, if $sig is 0 and the specified process exists, it returns true without actually terminating it.

and mixing alarm and sleep doesn't work well:

It is usually a mistake to intermix alarm and sleep calls, because sleep may be internally implemented on your system with alarm.

so talexb's suggestion seems spot on Re: Signal to a sleeping Perl program

while (! -e '/predefined/location/time_is_up') {
    do {'your thing'};
    sleep 900;
}
[download]

exit if -e '/predefined/location/time_is_up';
[download]

One way would be to break up the 15 minute sleep into smaller mini-sleeps. Presumably, waking up would allow your script to respond to the request to terminate.

One way would be to break up the 15 minute sleep into smaller mini-sleeps. Presumably, waking up would allow your script to respond to the request to terminate.

Any signal, or at least any non-ignored signal interrupts sleep. No need for polling. See also sleep:

Causes the script to sleep for (integer) EXPR seconds, or forever if no argument is given. Returns the integer number of seconds actually slept.

May be interrupted if the process receives a signal [...]

Note: sleep() returns how long it actually slept, so your program can continue sleeping for the remaining time if some signal happened in between.

The C API sleep() behaves similar, see sleep(3), but it returns the remaining sleep time, not the time actually slept.

Alexander

--
Today I will gladly share my knowledge and experience, for there are no sweeter words than "I told you so". ;-)

Any signal, or at least any non-ignored signal interrupts sleep.

Many forget this, and expect that a literal sleep 60 may not actually take 60s, but could be anything less than that. In one-off scripts I've seen code like this (untested):

sub my_sleep {
    my $sleep_time = (shift or 1); # total time to sleep
    my $sleep_interval = (shift or 10); # wake up at least this often
    my $start = time;
    $stop_time = $start + $sleep_time;
    while (time < $stop_time) {
        sleep $sleep_time;
        # handle wake up tasks
    }
    my $elapsed = time - $start;
    return $elapsed; # total time actually slept (plus shipping and ha
+ndling)
}
[download]

You may want additional conditions, and use this as a timeout mechanism. There's probably a nice module for that, or roll your own.

But the point is sleep comes with an unspoken if (...), if something else doesn't wake me up.

-QM
--
Quantum Mechanics: The dreams stuff is made of

Handled signals causes blocking system calls to be interrupted (so the signal can be handled). You need to handle those errors.

sub uninterruptible_sleep {
   my $sleep_until = time() + $_[0];
   while (1) {
      my $time_left = $sleep_until - time();
      return if $time_left <= 0;

      sleep($time_left);
   }
}
[download]

Try using select instead of sleep - at least on linux it does not rely on ALRM, it's a single system call.

#!/usr/bin/perl

use strict; # https://perlmonks.org/?node_id=11111522
use warnings; # borrowed from choroba
use feature qw{ say };

local $SIG{USR1} = sub 
  {
  say STDERR "Signal 1 caught.";
  };

local $SIG{USR2} = sub 
  {
  say STDERR "Bye!";
  exit
  };

my $sum = 0;
while (1) 
  {
  $sum += $_  for 1 .. 100;
  say $sum;

  say STDERR scalar localtime, " Sleeping...";
  select undef, undef, undef, 10;

  say STDERR scalar localtime, " Ready!";
  }
[download]

I don't have a Solaris to test on, but this works as expected on my linux system.

Maybe you should have replied earlier, most of us thought you are on Windows.

Cheers Rolf
_{(addicted to the Perl Programming Language :)
Wikisyntax for the Monastery FootballPerl is like chess, only without the dice}

So it's solved! Thanks for the info!

The thread is long, this info might get overlooked.

It would have been nice tho if the OP used a SSCCE from the start and responded quicker.

Cheers Rolf
_{(addicted to the Perl Programming Language :)
Wikisyntax for the Monastery FootballPerl is like chess, only without the dice}

UPDATED

redacted snarky remark.