In addition to the errors that have already been pointed out to you (especially the fact that you don't have a test2 subroutine), please note that you should pass a string as a parameter to your sub:

test2(1.00.000);
[download]

should be:

test2("1.00.000");
[download]

I would also submit that this:

sub test2 {
    my ($var2) = @_;
    return ("One")    if ($var2 =~ /^1/ );
    return ("Two")    if ($var2 == /^2/ );
    return ("Three")  if ($var2 == /^3/ );
    return undef;
}
[download]

is not correct for input values starting with 2 and 3 and is not very efficient in terms of performance, nor in terms of coding simplicity. Immediate correction of the error is to replace == with =~ for cases 2 and 3:

sub test2 {
    my ($var2) = @_;
    return ("One")    if ($var2 =~ /^1/ );
    return ("Two")    if ($var2 =~ /^2/ );
    return ("Three")  if ($var2 =~ /^3/ );
    return undef;
}
[download]

Note that Marshall corrected these two errors, but I thought it would be useful to point these out to you for your benefit. An additional improvement would be to remove the triple regex and to extract the first digit from the string only once:

sub test2 {
    my $var2 = substr shift, 0, 1;
    return ("One")    if $var2 == 1 ;
    return ("Two")    if $var2 == 2 ;
    return ("Three")  if $var2 == 3 ;
    return undef;
}
[download]

Doing the extraction of the first digit only once is cleaner, removes the risk of the error I pointed out just above and is likely to be faster if that matters (although it is true that an anchored regex is pretty fast). And it paves the way for yet another improvement, the use of an array rather than multiple evaluations. The full program may now be this:

use strict;
use warnings;
my @translation = qw / Zero One Two Three/;

sub test2 {
    return $translation[(substr shift, 0, 1)];
}
print test2("1.00.000");
[download]

Now, assuming you have a very large amount of data and performance matters, we may want to benchmark this against your (corrected) triple regex version and an intermediate solution extracting the first digit only once:

use strict;
use warnings;
use Benchmark  qw/cmpthese/;
my @translation = qw / Zero One Two Three/;

sub test1 {
    my $var2 = shift;
    return ("One")    if ($var2 =~ /^1/ );
    return ("Two")    if ($var2 =~ /^2/ );
    return ("Three")  if ($var2 =~ /^3/ );
    return undef;
}
sub test2 {
    my $var2 = substr shift, 0, 1;
    return ("One")    if ($var2 == 1 );
    return ("Two")    if ($var2 == 2 );
    return ("Three")  if ($var2 == 3 );
    return undef;
}
sub test3 {
    return $translation[(substr shift, 0, 1)];
}
cmpthese( -1,
    {
    test_1 => sub {test1("3.01.000")},
    test_2 => sub {test2("3.01.000")},
    test_3 => sub {test3("3.01.000")},
    }
)
[download]

which gives the following results:

$ perl test_if.pl
            Rate test_1 test_2 test_3
test_1 1294050/s     --   -11%   -51%
test_2 1451608/s    12%     --   -45%
test_3 2642856/s   104%    82%     --
[download]

As you can see, the array solution is about twice faster. Having said that, performance is often not so important (it is often fast enough anyway), and I am using quite regularly solutions similar to Marshall's proposals.