A little bench-marking can be helpful. For the case of converting an array to a hash where the array values become keys and the array index become values.

I've bench-marked the OP code as well as the variations presented in response, in addition I added my own solution to the problem (variation3). The clear winner is variation1.

my %hash; @hash{ @array } = 0 .. $#array;
[download]

#!/usr/bin/env perl
use strict;
use warnings;

use Benchmark qw(:all);

my @array=qw(a b c d e f g h);

sub original {
  my %hash;
  for (my $idx=0; $idx<@array; $idx++) { $hash{$array[$idx]} = $idx;}
}

sub variation1 {
  my %hash;
  @hash{ @array } = 0 .. $#array;
}

sub variation2 {
  my %hash = map { $array[$_] => $_ } 0..$#array;
}

sub variation3 {
  my $idx = 0;
  my %hash = map { $_ => $idx++ } @array;
}

cmpthese(-10, {
   'original' => sub{
       original()
       },
   'variation1' => sub{
       variation1()
       },
   'variation2' => sub{
       variation2()
       },
   'variation3' => sub{
       variation3()
       },
});
[download]

               Rate variation2 variation3   original variation1
variation2 142570/s         --       -15%       -35%       -49%
variation3 168018/s        18%         --       -24%       -40%
original   220185/s        54%        31%         --       -21%
variation1 279147/s        96%        66%        27%         --
[download]