#!/usr/bin/env perl

use strict;
use warnings;

my $rand_bias; # Boolean (for testing)
my ($x_high, $y_high) = (80, 80);
my $N = 10_000;

for my $rand_bias_bool (0, 1) {
    $rand_bias = $rand_bias_bool;
    print '*** ', $rand_bias ? 'WITH' : 'NO', ' RANDOM BIAS', " ***\n";

    my @points = map [ gen_rand($x_high), gen_rand($y_high) ], 1 .. $N; 

    print_matrix(\@points);
}

sub gen_rand {
    my $rand_high = shift;
    return int rand $rand_high unless $rand_bias; # For testing only!

    my $high_part = $rand_high;
    my $rand_sum = 0;

    while ($high_part) {
        my $rand_arg = 1 + int rand $high_part;
        $high_part -= $rand_arg;
        $rand_sum += int rand $rand_arg;
    }

    return $rand_sum;
}

sub print_matrix {
    my $coords = shift;
    my %matrix;

    for (@$coords) {
        my ($x, $y) = @$_;
        ++$matrix{$x}{$y};
    }

    for my $y (reverse 0 .. $y_high - 1) {
        for my $x (0 .. $x_high - 1) {
            if (exists $matrix{$x}{$y}) {
                $matrix{$x}{$y} = '@' if $matrix{$x}{$y} > 9;
            }
            else {
                $matrix{$x}{$y} = ' ';
            }
            print $matrix{$x}{$y}; 
        }

        print "\n";
    }
}