#!/usr/bin/perl -w
use strict;

my $depth  = 0;
my $count  = 0;
my $ddepth = 3;

use LWP::Simple;
my $html = get('http://grinder.perlmonk.org/hp4600/');

my %Device;

use Data::Dumper;

use HTML::TableExtract;
my $te = HTML::TableExtract->new;
$te->parse($html);
foreach my $ts ($te->table_states) {
  &process_detail($ts) if ($ts->depth == $ddepth);
  &process_main($ts)   if ($ts->depth == $depth && $ts->count == $count);
}
# Clean up the empty spots
@{$Device{stats}} = grep(defined, @{$Device{stats}});

print Dumper(\%Device);

exit;

sub process_main {
  my $ts = shift;
  my($host, $model) = _scrub(($ts->rows)[1]);
  $Device{host}  = $host;
  $Device{model} = $model;
}

sub process_detail {
  $_[0]->count % 2 ? _proc_detail_stats(@_) : _proc_detail_name(@_);
}

sub _proc_detail_name {
  my $ts = shift;
  my($name, $part, $pct) = _scrub(($ts->rows)[0]);
  $part =~ s/.*:\s+//;
  $Device{stats}[$ts->count] =
    { name => $name, part => $part, pct => $pct };
}

sub _proc_detail_stats {
  my $ts = shift;
  my @stats = map(_scrub($_), $ts->rows);
  my $i = $ts->count - 1;
  @{$Device{stats}[$i]}{qw(pages_left hist low serial_num pages_printed)}
    = (map(_scrub($_), $ts->rows))[1,2,4,6,8];
}

sub _scrub {
   grep(!/^\s*$/s, map(split(/(^M|\n)+/,$_), @{shift()}));
}