#!/usr/bin/perl
use strict;
use warnings;
use Getopt::Long;
use ExtUtils::ModuleMaker 0.204;

my %author = 
(
    NAME      => 'Christopher Baker',
    EMAIL     => 'ignatz@ignatzmouse.com',
    # CPANID    => 'IGNATZ', Someday *SIGH*
    WEBSITE   => 'http://www.ignatzmouse.com'
);

# Set some defaults
my $license         = 'perl';
my $version         = '0.01';
my $module_name     = '';
my $compact         = 2;
my $extra_modules   = '';
my @extra_modules   = ();

GetOptions
(
    'name=s'      => \$module_name, 
    'version:f'   => \$version, 
    'license:s'   => \$license, 
    'extra:s'     => \$extra_modules,
    'compact:i'   => \$compact
);

Usage() unless $module_name;

###############################################################################
# Now make the module
###############################################################################

push @extra_modules, {NAME => $_, ABSTRACT => $_}
    for split /,/, $extra_modules;

Generate_Module_Files
(
    NAME           => $module_name,
    ABSTRACT       => $module_name,
    AUTHOR         => \%author,
    VERSION        => $version,
    LICENSE        => $license,
    compact        => $compact, # Module uses wrong option case, not COMPACT
    EXTRA_MODULES  => \@extra_modules
);

if ($compact == 2) 
{
    my $dir_name = $module_name;
    $dir_name =~ s/::/-/g;

    print STDERR "renaming '$dir_name' to '$dir_name-$version'\n"; 
    rename $dir_name, "$dir_name-$version" 
        or warn "Could not rename '$dir_name' to '$dir_name-$version': $!";
}

sub Usage
{
    my ($prog) = $0 =~ /\/([^\/]+)$/;
print <<HELP;
$prog - Simple Module Maker

Usage: $prog <-name ModuleName> [-version=?] [-extra=?,?] [-license=?] [-compact=?]

Eg:    $prog -name My::Module
       $prog -name My::Module -version 0.11
                    -extra My::Utils,My::Extra -license perl

HELP
}