#!/usr/bin/env perl
use 5.10.0;
use strictures;
use WWW::Mechanize; # LWP::UserAgent is almost the same here.
use WWW::OAuth;
use Compress::Zlib;

my @symbols = grep /\A[A-Z.]+\z/, @ARGV;
die "Give a list of symbols; e.g., AAPL GHII AMZN XOM DIS PBF BABA JD AMD VOO\n"
    unless @symbols;

my $sym = join ",", @symbols;

die "Missing ENV values: ALLY_CLIENT_ID ALLY_CLIENT_SECRET ALLY_TOKEN ALLY_TOKEN_SECRET\n"
    unless $ENV{ALLY_CLIENT_ID}
    and $ENV{ALLY_CLIENT_SECRET}
    and $ENV{ALLY_TOKEN}
    and $ENV{ALLY_TOKEN_SECRET};

my $oauth = WWW::OAuth->new(
    client_id => $ENV{ALLY_CLIENT_ID},
    client_secret => $ENV{ALLY_CLIENT_SECRET},
    token => $ENV{ALLY_TOKEN},
    token_secret => $ENV{ALLY_TOKEN_SECRET} );

my $mech = WWW::Mechanize->new( autocheck => undef );
$mech->add_handler( request_prepare => sub { $oauth->authenticate($_[0]) } );

my $gunzip = inflateInit( WindowBits => 16 + MAX_WBITS )
            or die "Cannot create a inflation stream\n";

$mech->add_handler (
    response_data => sub {
	my ( $response, $ua, $h, $data ) = @_;
	$response->content(undef); # Else will append.
	my ( $buffer, $status ) = $gunzip->inflate($data);
	die "zlib error: $status" if length $status;
	say $buffer;
    });

$mech->get("https://stream.tradeking.com/v1/market/quotes?symbols=$sym");

__END__

##</code><code>##

#!/usr/bin/env perl
use 5.10.0;
use strictures;
use Mojo::UserAgent;
use WWW::OAuth;

my @symbols = grep /\A[A-Z.]+\z/, @ARGV;
die "Give a list of symbols; e.g., AAPL GHII AMZN XOM DIS PBF BABA JD AMD VOO\n"
    unless @symbols;

my $sym = join ",", @symbols;

die "Missing ENV values: ALLY_CLIENT_ID ALLY_CLIENT_SECRET ALLY_TOKEN ALLY_TOKEN_SECRET\n"
    unless $ENV{ALLY_CLIENT_ID}
    and $ENV{ALLY_CLIENT_SECRET}
    and $ENV{ALLY_TOKEN}
    and $ENV{ALLY_TOKEN_SECRET};

my $oauth = WWW::OAuth->new(
    client_id => $ENV{ALLY_CLIENT_ID},
    client_secret => $ENV{ALLY_CLIENT_SECRET},
    token => $ENV{ALLY_TOKEN},
    token_secret => $ENV{ALLY_TOKEN_SECRET} );

my $ua = Mojo::UserAgent->new( max_response_size => 0 ); # Stream means no max.
$ua->on( start => sub { $oauth->authenticate( $_[1]->req ) } ); # OAuth all requests.

my $tx = $ua->build_tx( GET => "https://stream.tradeking.com/v1/market/quotes?symbols=$sym" );

$tx->res->content
    ->unsubscribe("read")
    ->on( read => sub {
        my ( $content, $bytes ) = @_;
        say $bytes;
      });

$tx = $ua->start($tx);

__END__