#!/usr/bin/perl
use strict;
use warnings;

3 == @ARGV or die "USAGE: perl $0 filein fileout shopID\n";

my ($file_in, $file_out, $shopID) = @ARGV; # file_in == file3, file_out == fout.csv shopID == 2345

open my $in, '<', $file_in or die "Unable to open $file_in: $!";
open my $out, '>', $file_out or die "Unable to open $file_out: $!";

chomp(my @hdrs = split /,/, <$in>);

my @cols = split /\n/, <<EndCols;
Cust Code
Inv Num
MobileNumber
Inv Date
PosId
PosUserID
ShopID
Prodcode
ProdDiscription
ProdDept
ProdGroup1
ProdGroup2
Qty
Net Amt
EndCols

print $out "DeviceID,PosTxnID,MobileNumber,Timestamp,PosID,PosUserID,ShopID,Prodcode,ProdDescription,ProdDept,ProdGroup1,ProdGroup2,Qty,Value\n";

my %tmp;

while (<$in>) {
	next unless /^\S+\s-\s#\s/ .. /^,/;
	chomp;
	if (/^,/) {
		%tmp = ();	
	}
	elsif (/^(ZB\d+)\s-\s#\s([^,]+)/) {
		$tmp{Prodcode} = $1;
		$tmp{ProdDiscription} = $2;
		$tmp{ShopID} = $shopID;	
	}
	else {
		@tmp{@hdrs} = split /,/;
		$tmp{'Inv Date'} = join("/", reverse split '/', $tmp{'Inv Date'});
		$tmp{'Inv Date'} .= ' 00:00';
		print $out join(",", map $_ // '', @tmp{@cols}), "\n";	
	}
}
close $in or die $!;
close $out or die $!