llil start
get_properties : 15 secs
sort + output  : 103 secs
total          : 118 secs

my_test start
get_properties : 31 secs
sort + output: 10 secs
total: 41 secs

##</code><code>##

use strict;
use warnings;
use feature 'say';

use Math::GMPz ':mpz';
use Sort::Packed 'sort_packed';

@ARGV or die "usage: $0 file...\n";
my @llil_files = @ARGV;

warn "my_test start\n";
my $tstart1 = time;

my $r = Rmpz_init;

Rmpz_set_str( $r, 'zzzzzz' =~ tr/a-z1-9/1-9a-z/r, 27 );
my $MAX = Rmpz_get_ui( $r );

my ( $buf_in, $buf_out ) = ( "\xFF" x $MAX, '' );

for my $fname ( @llil_files ) {
    open( my $fh, '<', $fname ) or die "error: open '$fname': $!";
    while ( <$fh> ) {
        chomp;
        my ( $word, $count ) = split /\t/;
        
        $word =~ tr/a-z1-9/1-9a-z/;
        Rmpz_set_str( $r, $word, 27 );
        vec( $buf_in, Rmpz_get_ui( $r ), 8 ) -= $count;
    }
    close( $fh ) or die "error: close '$fname': $!";
}

while ( $buf_in =~ /[^\xFF]/g ) {
    Rmpz_set_ui( $r, @- );
    $buf_out .= pack 'aa6', $&, Rmpz_get_str( $r, 27 ) =~ tr/1-9a-z/a-z/r
}

my $tend1 = time;
warn "get_properties : ", $tend1 - $tstart1, " secs\n";

my $tstart2 = time;
sort_packed C7 => $buf_out;
while ( $buf_out ) {
    my ( $count, $word ) = unpack 'Ca6', substr $buf_out, 0, 7, '';
    printf "%s\t%d\n", $word, 255 - $count
}
    
my $tend2 = time;
warn "sort + output: ", $tend2 - $tstart2, " secs\n";
warn "total: ", $tend2 - $tstart1, " secs\n";