use strict;
use warnings;
use feature 'say';
use MCE::Util;
use MCE::Map max_workers => MCE::Util::get_ncpu();
use Time::HiRes 'usleep';

my @output = mce_map_s {
    my $input = $_;
    my $n = $input;

    my @result = $input;

    while ( $n != 1 ) {
        $n = $n % 2 ? 3 * $n + 1 : $n / 2;
        usleep 20; # simulate extra computation
        push @result, $n;
    }

    return [ $input, scalar @result ];
} 1, 100000;

MCE::Map->finish;

@output = sort { $b->[1] <=> $a->[1] } @output;

say sprintf('%s : length %s', $_->[0], $_->[1]) for @output[0..19];

##</code><code>##

use strict;
use warnings;
use feature qw/say/;
use MCE::Util;
use MCE::Map max_workers => MCE::Util::get_ncpu();
use Time::HiRes qw/usleep/;

sub collatz_seq {
    my $n = shift;
    my @result;
    while ($n != 1) {
        my $new_n = $n % 2 ? 3 * $n + 1 : $n / 2;
        usleep 20; # simulate extra computation
        push @result, $new_n;
        $n = $new_n;
    }
    return @result;
}

my @long_seqs = mce_map_s {
    my $num = $_;
    my @seq = ($num, collatz_seq $num);
    return [ $num, scalar @seq ];
} 1, 100000;

MCE::Map->finish;

@long_seqs = sort { $b->[1] <=> $a->[1] } @long_seqs;
say  "$_->[0] : length $_->[1]" for @long_seqs[0..19];

##</code><code>##

use strict;
use warnings;
use feature qw/say/;
use constant MAX => 300000;
use MCE::Util;
use MCE::Map max_workers => MCE::Util::get_ncpu();
use Time::HiRes qw/usleep/;

my %cache;

sub collatz_seq {
    my $input = shift;
    my $n = $input;
    my @result;
    while ($n != 1) {
        if (exists $cache{$n}) {
            push @result, @{ $cache{$n} };
            last;
        }
        my $new_n = $n % 2 ? 3 * $n + 1 : $n / 2;
        usleep 20; # simulate extra computation
        push @result, $new_n;
        $cache{$n} = [ $new_n, @{ $cache{$new_n} } ]
            if $n < MAX && exists $cache{$new_n};
        $n = $new_n;
    }
    $cache{$input} = \@result if $n < MAX;
    return @result;
}

my @long_seqs = mce_map_s {
    my $num = $_;
    my @seq = ($num, collatz_seq $num);
    return [ $num, scalar @seq ];
} 1, 100000;

MCE::Map->finish;

@long_seqs = sort { $b->[1] <=> $a->[1] } @long_seqs;
say  "$_->[0] : length $_->[1]" for @long_seqs[0..19];

##</code><code>##

77031 : length 351
52527 : length 340
78791 : length 338
60975 : length 335
87087 : length 333
88059 : length 333
91463 : length 333
63387 : length 330
95081 : length 328
99067 : length 328
99721 : length 328
71310 : length 325
71311 : length 325
74791 : length 325
74793 : length 325
35655 : length 324
53483 : length 322
56095 : length 322
80225 : length 320
81159 : length 320

##</code><code>##

   Nick's example:  1m32.958s real, 0m56.561s user - no caching
Laurent's example:  1m33.454s real, 1m00.491s user - no caching
Laurent's example:  0m18.761s real, 0m20.990s user -    caching