#!/usr/bin/perl

use strict;
use warnings;
use autodie qw( open close );
use Fcntl qw( LOCK_EX LOCK_UN );

sub say
{
        print scalar localtime(),' pid=',$$,': ',@_,"\n";
}

my $mainpid=$$;
my $pid=fork() // die "Can't fork: $!";
# in both parent and child process, install signal handler
$SIG{'ALRM'}=sub { warn 'SIGALRM in ',$$==$mainpid ? 'main' : 'helper' };
if ($pid) {
        # parent process
        say "main starts";
        say "main waiting for helper to lock";
        sleep 1;
        open my $f,'>','tempfile.tmp';
        alarm(5);
        say "main flock";
        flock($f,LOCK_EX) or say "main can't lock: $! (error code ",0+$!,')';
        say "main flock done";
        alarm(0);
        close $f;
        say "main ends";
        wait;
} else {
        # child process
        say "helper starts";
        open my $f,'>','tempfile.tmp';
        flock($f,LOCK_EX) or die "Helper can't lock: $!";
        select(undef,undef,undef,10);
        flock($f,LOCK_UN) or die "Helper can't unlock: $!";
        close $f;
        say "helper ends";
        exit(0);
}