#!/usr/bin/perl

# http://perlmonks.org/?node_id=1204060

use strict;
use warnings;

my @points = points();
my ($minx, $miny, $maxx, $maxy) = (
  $points[0][0], $points[0][1], $points[0][0], $points[0][1]);

for (@points)
  {
  my ($x, $y) = @$_;
  $minx > $x and $minx = $x;
  $miny > $y and $miny = $y;
  $maxx < $x and $maxx = $x;
  $maxy < $y and $maxy = $y;
  }

my $height = $maxy - $miny + 3;  # some useful stuff
my $width = $maxx - $minx + 3;
my $gw = $width + 1; # grid width (distance to down one row)
my $gwm3 = $gw - 3;
my @letters = ('A' .. 'Z', 'a' .. 'z'); # label points by letter sequence
my @steps = (1, $gw+1, $gw, $gw-1, -1, -$gw-1, -$gw, -$gw+1); # by direction
my $grid = ( ' ' x $width . "\n" ) x $height;
my @answerpoints; # coordinates around edge

for (@points) # put points on grid (multiline string :)
  {
  my ($x, $y) = @$_;
  substr $grid, (($y - $miny + 1)) * $gw + ($x - $minx + 1), 1, '#';
  }

my $direction = 0; # start facing east (increases clockwise)
my $start = my $at = $grid =~ /(?<= )#/ ? $-[0] : die "empty"; # at topleft

do # clockwise walk around edge
  {
  push @answerpoints, [ $at % $gw - 1 + $minx, int $at / $gw - 1 + $miny ];
  pos($grid) = $at - $gw - 1; # northwest corner neighbor
  $grid =~ /\G(.)(.)(.).{$gwm3}(.).(.).{$gwm3}(.)(.)(.)/s; # all neighbors
  ("$1$2$3$5$8$7$6$4" x 2) =~ /^.{$direction} *(#)/ and # rotate & scan
    $at += $steps[ $direction = ( $-[1] - 3 ) % 8 ]; # step in new direction
  }
until( $at == $start );

my $i = 0;
for (@answerpoints) # add letters for display if wanted
  {
  my ($x, $y) = @$_;
  pos($grid) = $x - $minx + 1 + ($y - $miny + 1) * $gw;
  $grid =~ s/\G#/$letters[$i++ % @letters]/; # label point if not
  }
print $grid;

#use Data::Dump 'pp'; pp \@answerpoints; # the real answer :)

sub points
  {
  [527,83],[527,84],[526,84],[525,84],[524,84],[523,84],[522,84],
  ... some points deleted to shorten listing ...
  [534,113],[533,113],[532,113],[531,113],[530,113],
  }