# W2H_1.pm                                                  15feb20waw

package W2H_1;

use 5.010;  # need regex extensions

use strict;
use warnings;

# use Data::Dump qw(pp dd);  # for debug

use constant DEBUG => 0;
use constant {
    DBPR_rx => 0 && DEBUG,
    };

my %w2h_map = qw(* b   / i   _ u);  # wiki markup -> HTML tag mapping

my $mq_wiki_mark = quotemeta join '', keys %w2h_map;  # meta-quoted wiki

my $rx_wml = qr{
  ((?&PRE_OPEN) (?&WIKI_MARK))                            # $1: opening wikimark
  ((?: (?: (?: (?! \g-2 (?&POST_CLOSE)) .)*+) | (?R) )*)  # $2: marked body
  \g-2 (?&POST_CLOSE)                                     # closing wikimark

  (?(DEFINE)
    (?<PRE_OPEN>   (?<! [^>\s$mq_wiki_mark]))  # after string start, > or \s or wml
    (?<POST_CLOSE> (?!  [^<\s$mq_wiki_mark]))  # before string end,  < or \s or wml
    (?<WIKI_MARK>  [\Q$mq_wiki_mark\E])
    )

  }xms;
DBPR_rx and print $rx_wml, "\n";

# only used for development diagnostics
my $rx_pre_open   = qr{ (?<! [^\s>]) }xms;
my $rx_post_close = qr{ (?!  [^\s<]) }xms;
my $rx_wiki_mark  = qr{ [$mq_wiki_mark] }xms;

# only used for development diagnostics
die q{bad '\A wm' match} unless '_'  =~ m{ $rx_pre_open   $rx_wiki_mark  }xms;
die q{bad '\s wm' match} unless ' _' =~ m{ $rx_pre_open   $rx_wiki_mark  }xms;
die q{bad '> wm'  match} unless '>_' =~ m{ $rx_pre_open   $rx_wiki_mark  }xms;

die q{bad 'wm \z' match} unless '_'  =~ m{ $rx_wiki_mark  $rx_post_close }xms;
die q{bad 'wm \s' match} unless '_ ' =~ m{ $rx_wiki_mark  $rx_post_close }xms;
die q{bad 'wm <'  match} unless '_<' =~ m{ $rx_wiki_mark  $rx_post_close }xms;

# subroutines ######################################################

sub w2h {  # not exported; invoke fully-qualified

    my ($wiki,  # string possibly containing wiki markup
        ) = @_;

    (my $html = $wiki) =~ s{
        $rx_wml  # captures to $1 $2
        }
        { my ($html_tag, $body) = ($w2h_map{$1}, w2h($2));
          "<$html_tag>$body</$html_tag>";
        }xmsge;

    return $html;

    }

1;