#!/usr/bin/perl

use strict;
use warnings;
use Imager;
use MCE::Loop;

STDOUT->autoflush;

my $count = 0;
my @data;

MCE::Loop->init(
  max_workers => MCE::Util::get_ncpu(),
  chunk_size  => 100,
  init_relay  => '',
  gather      => sub {
    if (@_ == 1) {
      print "\r", $count++;
    } else {
      push @data, @{ $_[1] };
    }
  }
);

mce_loop {
  my ($mce, $chunk_ref, $chunk_id) = @_;
  my @i_data;

  for my $x (@{ $chunk_ref }) {
    my $i = Imager->new(xsize=>120, ysize=>50)
    or die  Imager->errstr;
  
    $i->string(
      text  => $x,
      color => Imager::Color->new('ffffff'),
      font  => Imager::Font->new(
        file  => '/usr/share/fonts/truetype/msttcorefonts/cour.ttf',
      # file  => '/System/Library/Fonts/Courier.dfont',
      # face  => 'Courier New', # mswin
        size  => 42,
        aa    => 1),
      x     => 5,
      y     => 35
    );

    # One cannot serialize Imager objects or will crash.
    # Instead save the image to a scalar and send that.
    # The manager process later reads from scalar refs.

    $i->write(data => \my $data, type => 'gif');
    push @i_data, $data;

    MCE->gather($x);
  }

  MCE::relay { MCE->gather($chunk_id, \@i_data) };

} [ 0 .. 9999 ];

MCE::Loop->finish;

Imager->write_multi({
  file => 'gif.gif', type => 'gif', gif_loop => 0, gif_delay => 1
}, map { Imager->read_multi(data => \$_) } @data) or die Imager->errstr;

print " frame GIF done!\n";