package Acmecorp::Contact;
use base qw(Foobar_Super Common);

use strict; 
use warnings;
use MIME::Lite;    #load any extra modules needed
use Date::Calc qw(Today);

#--- SETUP Runmodes

sub setup {
   my $self = shift;
   $self->start_mode('d');         #if no runmode, use 'd'
   $self->mode_param('rm');
   $self->run_modes(
      'd'         => 'display',
      's'         => 'save_form'
   );
}

#--- Display 

sub display {
   my $self = shift;
   
    my $template = $self->load_tmpl( 'contact.tmpl',
                                      die_on_bad_params => 0 );
                                      
   $template->param( today => sprintf( '%4d-%02d-%02d', Today() ) );                                   

   return $template->output();
}

#--- Process 

sub save_form {
   my $self = shift;
   
   my ( %sql, @errors, $error, $fifvalues );
   
   ($sql{'name'}, $error ) = $self->validate( $self->query->param('name') );
      if ( $error ) { push @errors, ( { 'error' => 'Name'.$error } ); }
   ($sql{'address'}, $error ) = $self->validate( $self->query->param('address') );
      if ( $error ) { push @errors, ( { 'error' => 'Address'.$error } ); }
   ($sql{'city'}, $error ) = $self->validate( $self->query->param('city') );
      if ( $error ) { push @errors, ( { 'error' => 'City'.$error } ); }
   $sql{'more_info'} = $self->query->param('more_info');

   #if there are errors, return the form with original input and error messages 
   if ( @errors ) { 
      my $template = $self->load_tmpl( 'contact.tmpl',
                                        die_on_bad_params => 0,
                                     );
   
      $template->param( errors => \@errors,
                        today  => sprintf( '%4d-%02d-%02d', Today() ),
                      );
   
      for my $key ( keys %sql ) { 
         $fifvalues->{$key} = $sql{$key}; #assign fill-in-form values
      }

      return $self->fill_form( \$template->output, $fifvalues );
      
   } else {
   
      $self->record(\%sql);  #record the input
      
      return $self->redirect('/thankyou.html');
   }   

}

#--- Record

sub record {
   my $self = shift;
   my $sql  = shift;
   my %sql  = %{ $sql };

	#we use CAP::DBH to connect to the DB and execute our SQL statement
   my $stmt = 'INSERT INTO contacts (' . join(',', keys %sql) . ') 
                  VALUES (' . join(',', ('?') x keys %sql) . ')';
   $self->dbh->do($stmt, undef, values %sql);   
}   
1;

<p><b>Common.pm</b> (a module with common methods)</p>
package Common;

sub validate {
   my $self = shift;
   my $to_check = shift;
   
   if ( $to_check !~ /^([\w ]+)$/ ) {
      return ( $to_check, " has invalid characters or is blank" );
   } else {
      return $1;
   }
}
1;